- Support FilesystemHierarchyStandard on Linux/Unix using preprocessor macros in .pro files.

- Add support for "make install" and "qmake PREFIX=" to improve YACReader packageability.
- Add .desktop files for YACReader and YACReaderLibrary X11 desktop integration.
- Add central YACReader.pro file as alternative to compileX11.sh
- Add p7zip patch support and sourcecode check to .pro files

YACReaderLibrary/YACReaderLibrary.pro

@@ -19,7 +19,6 @@ win32 {
 
 LIBS += -L../dependencies/poppler/lib -loleaut32 -lole32 -lshell32
 
-
 isEqual(QT_MAJOR_VERSION, 5) {
 LIBS += -lpoppler-qt5
 INCLUDEPATH += ../dependencies/poppler/include/qt5
@@ -36,6 +35,8 @@ CONFIG -= embed_manifest_exe
 
 unix:!macx{
 
+QMAKE_CXXFLAGS += -std=c++11
+
 isEqual(QT_MAJOR_VERSION, 5) {
 INCLUDEPATH  += /usr/include/poppler/qt5
 LIBS         += -L/usr/lib -lpoppler-qt5
@@ -190,3 +191,54 @@ isEqual(QT_MAJOR_VERSION, 5) {
 	Release:DESTDIR = ../release
 	Debug:DESTDIR = ../debug
 }
+
+win32:!exists (../compressed_archive/lib7zip) {
+	error(You\'ll need 7zip source code to compile YACReader. \
+	Please check the compressed_archive folder for further instructions.)
+}
+
+unix:exists (../compressed_archive/libp7zip) {
+	message(Found p7zip source code...)
+	system(patch -d ../compressed_archive -N -p0 -i libp7zip.patch)
+} else {
+	error(You\'ll need 7zip source code to compile YACReader. \
+	Please check the compressed_archive folder for further instructions.)
+}
+
+unix:!macx {
+#set install prefix if it's empty
+isEmpty(PREFIX) {
+	PREFIX = /usr
+}
+
+BINDIR = $$PREFIX/bin
+LIBDIR = $$PREFIX/lib
+DATADIR = $$PREFIX/share
+
+DEFINES += "LIBDIR=\\\"$$LIBDIR\\\""  "DATADIR=\\\"$$DATADIR\\\"" "BINDIR=\\\"$$BINDIR\\\""
+
+#MAKE INSTALL
+INSTALLS += bin icon desktop server translation
+
+bin.path = $$BINDIR
+isEmpty(DESTDIR) {
+	bin.files = YACReaderLibrary
+} else {
+	bin.files = $$DESTDIR/YACReaderLibrary
+}
+
+server.path = $$DATADIR/YACReader
+server.files = ../release/server
+
+icon.path = $$DATADIR/YACReader
+icon.prefix = ../images
+icon.files = iconLibrary.png db.png coversPackage.png
+
+desktop.path = $$DATADIR/applications
+desktop.extra = desktop-file-edit --set-icon=$$DATADIR/YACReader/iconLibrary.png $$PWD/../YACReaderLibrary.desktop
+desktop.files = ../YACReaderLibrary.desktop
+#TODO: icons should be located at /usr/share/icons and have the same basename as their application
+
+translation.path = $$DATADIR/YACReader/languages
+translation.files = ../release/languages/yacreaderlibrary_*
+}