mirror of
https://invent.kde.org/frameworks/kimageformats.git
synced 2025-06-03 17:08:08 -04:00
adc5c7ae9a
The following changes have been made: - Improved writing speed by using scanLine() instead of pixel() - Optimized memory usage on writing by using ScanlineConverter class - Added native write support for RGBA32FPx4, RGBA16FPx4, RGB8, Grayscale8 and Indexed8 uncompressed formats - Grayscale DDS without alpha are loaded in a Grayscale8 image - Fixed warnings about wrong PITCH reported by GIMP on DDSs saved by this plugin - Initial support for loading DX10 formats (R16F, RG16F, RGBA16F, RGBPreMulA16F, R32F, RG32F, RGBA32F, RGBPreMulA32F) - Fixed alignment issues and A8P8 format support of the attached images* Tested using GIMP and [NVIDIA Texture Tools](https://developer.nvidia.com/texture-tools-exporter) plugin for Photoshop. (*) The following images (taken from [here](https://github.com/walbourn/directxtexmedia)) cannot be added to read tests due to license issue: [test8_DWORD.dds](/uploads/449b5a0d886aaf6764af554fe38e2b09/test8_DWORD.dds) [dx5_logo.dds](/uploads/6f5f27df752890b227ef07e0195435d4/dx5_logo.dds) [test888_DWORD.dds](/uploads/c8bc355c5749cf203d47e0b3073ad419/test888_DWORD.dds)
166 lines
4.8 KiB
CMake
166 lines
4.8 KiB
CMake
# NB: the desktop files are installed for the benefit of KImageIO in KDELibs4Support.
|
|
|
|
##################################
|
|
|
|
function(kimageformats_add_plugin plugin)
|
|
set(options)
|
|
set(oneValueArgs)
|
|
set(multiValueArgs SOURCES)
|
|
cmake_parse_arguments(KIF_ADD_PLUGIN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
|
if(NOT KIF_ADD_PLUGIN_SOURCES)
|
|
message(FATAL_ERROR "kimageformats_add_plugin called without SOURCES parameter")
|
|
endif()
|
|
|
|
qt_add_plugin(${plugin} PLUGIN_TYPE imageformats)
|
|
target_sources(${plugin} PRIVATE ${KIF_ADD_PLUGIN_SOURCES})
|
|
set_target_properties(${plugin} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/imageformats)
|
|
target_link_libraries(${plugin} PRIVATE Qt6::Gui)
|
|
install(TARGETS ${plugin} DESTINATION ${KDE_INSTALL_QTPLUGINDIR}/imageformats)
|
|
endfunction()
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_ani SOURCES ani.cpp)
|
|
|
|
##################################
|
|
|
|
if (TARGET avif)
|
|
kimageformats_add_plugin(kimg_avif SOURCES "avif.cpp")
|
|
target_link_libraries(kimg_avif PRIVATE "avif")
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if(KIMAGEFORMATS_DDS)
|
|
kimageformats_add_plugin(kimg_dds SOURCES dds.cpp scanlineconverter.cpp)
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if (BUILD_EPS_PLUGIN)
|
|
if (TARGET Qt6::PrintSupport)
|
|
kimageformats_add_plugin(kimg_eps SOURCES eps.cpp)
|
|
target_link_libraries(kimg_eps PRIVATE Qt6::PrintSupport)
|
|
endif()
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if(OpenEXR_FOUND)
|
|
kimageformats_add_plugin(kimg_exr SOURCES exr.cpp scanlineconverter.cpp)
|
|
if(TARGET OpenEXR::OpenEXR)
|
|
target_link_libraries(kimg_exr PRIVATE OpenEXR::OpenEXR)
|
|
else()
|
|
if(OpenEXR_VERSION_STRING VERSION_LESS 2.3.0)
|
|
# Older OpenEXR versions use dynamic exception specifications, so
|
|
# cannot use C++17 with them
|
|
set_target_properties(kimg_exr PROPERTIES CXX_STANDARD 14)
|
|
endif()
|
|
target_link_libraries(kimg_exr PRIVATE OpenEXR::IlmImf)
|
|
endif()
|
|
kde_target_enable_exceptions(kimg_exr PRIVATE)
|
|
endif()
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_hdr SOURCES hdr.cpp)
|
|
|
|
##################################
|
|
|
|
if (LibHeif_FOUND)
|
|
kimageformats_add_plugin(kimg_heif SOURCES heif.cpp)
|
|
target_link_libraries(kimg_heif PRIVATE PkgConfig::LibHeif)
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if (LibJXL_FOUND AND LibJXLThreads_FOUND)
|
|
kimageformats_add_plugin(kimg_jxl SOURCES jxl.cpp)
|
|
target_link_libraries(kimg_jxl PRIVATE PkgConfig::LibJXL PkgConfig::LibJXLThreads)
|
|
if(LibJXL_VERSION VERSION_GREATER_EQUAL "0.9.0")
|
|
if(LibJXLCMS_FOUND)
|
|
target_link_libraries(kimg_jxl PRIVATE PkgConfig::LibJXLCMS)
|
|
else()
|
|
message(SEND_ERROR "libjxl_cms was not found!")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_pcx SOURCES pcx.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_pic SOURCES pic.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_pfm SOURCES pfm.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_psd SOURCES psd.cpp scanlineconverter.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_pxr SOURCES pxr.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_qoi SOURCES qoi.cpp scanlineconverter.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_ras SOURCES ras.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_rgb SOURCES rgb.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_sct SOURCES sct.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_tga SOURCES tga.cpp)
|
|
|
|
##################################
|
|
|
|
kimageformats_add_plugin(kimg_xcf SOURCES xcf.cpp)
|
|
|
|
##################################
|
|
|
|
if (LibRaw_FOUND)
|
|
kimageformats_add_plugin(kimg_raw SOURCES raw.cpp)
|
|
kde_enable_exceptions()
|
|
target_link_libraries(kimg_raw PRIVATE LibRaw::LibRaw)
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if (LibJXR_FOUND)
|
|
kimageformats_add_plugin(kimg_jxr SOURCES jxr.cpp)
|
|
kde_enable_exceptions()
|
|
target_include_directories(kimg_jxr PRIVATE ${LIBJXR_INCLUDE_DIRS})
|
|
target_link_libraries(kimg_jxr PRIVATE ${LIBJXR_LIBRARIES})
|
|
target_compile_definitions(kimg_jxr PRIVATE INITGUID)
|
|
if (NOT CMAKE_SYSTEM_NAME STREQUAL "Windows")
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=undef")
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-error=undef")
|
|
endif()
|
|
endif()
|
|
|
|
##################################
|
|
|
|
if (KF6Archive_FOUND)
|
|
|
|
kimageformats_add_plugin(kimg_kra SOURCES kra.cpp)
|
|
target_link_libraries(kimg_kra PRIVATE KF6::Archive)
|
|
|
|
kimageformats_add_plugin(kimg_ora SOURCES ora.cpp)
|
|
target_link_libraries(kimg_ora PRIVATE KF6::Archive)
|
|
|
|
endif()
|