refactor: Restructure project into sources/tests layout and dissolve PluginLLMCore

sources/ChatView/qml/chatparts/ChatItem.qml

@@ -0,0 +1,407 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import ChatView
+import QtQuick.Controls
+import QtQuick.Layouts
+import UIControls
+
+Rectangle {
+    id: root
+
+    property alias msgModel: msgCreator.model
+    property alias messageAttachments: attachmentsModel.model
+    property alias messageImages: imagesModel.model
+    property string chatFilePath: ""
+    property string textFontFamily: Qt.application.font.family
+    property string codeFontFamily: {
+        switch (Qt.platform.os) {
+        case "windows":
+            return "Consolas";
+        case "osx":
+            return "Menlo";
+        case "linux":
+            return "DejaVu Sans Mono";
+        default:
+            return "monospace";
+        }
+    }
+    property int textFontSize: Qt.application.font.pointSize
+    property int codeFontSize: Qt.application.font.pointSize
+    property int textFormat: 0
+    property Flickable chatViewport: null
+
+    property bool isUserMessage: false
+    property int messageIndex: -1
+
+    property int promptTokens: 0
+    property int completionTokens: 0
+    property int cachedPromptTokens: 0
+    property int reasoningTokens: 0
+
+    signal resetChatToMessage(int index)
+    signal openFileRequested(string filePath)
+
+    height: msgColumn.implicitHeight + 10
+    radius: 8
+    color: isUserMessage ? palette.alternateBase
+                         : palette.base
+
+    HoverHandler {
+        id: mouse
+    }
+
+    ColumnLayout {
+        id: msgColumn
+
+        x: 5
+        width: parent.width - x
+        anchors.verticalCenter: parent.verticalCenter
+        spacing: 5
+
+        Repeater {
+            id: msgCreator
+            delegate: Loader {
+                id: msgCreatorDelegate
+                // Fix me:
+                // why does `required property MessagePart modelData` not work?
+                required property var modelData
+
+                Layout.preferredWidth: root.width
+                sourceComponent: {
+                    // If `required property MessagePart modelData` is used
+                    // and conversion to MessagePart fails, you're left
+                    // with a nullptr. This tests that to prevent crashing.
+                    if(!modelData) {
+                        return undefined;
+                    }
+
+                    switch(modelData.type) {
+                        case MessagePartType.Text: return textComponent;
+                        case MessagePartType.Code: return codeBlockComponent;
+                        default: return textComponent;
+                    }
+                }
+
+                Component {
+                    id: textComponent
+                    TextComponent {
+                        itemData: msgCreatorDelegate.modelData
+                    }
+                }
+
+                Component {
+                    id: codeBlockComponent
+                    CodeBlockComponent {
+                        itemData: msgCreatorDelegate.modelData
+                    }
+                }
+            }
+        }
+
+        Flow {
+            id: attachmentsFlow
+
+            Layout.fillWidth: true
+            visible: attachmentsModel.model && attachmentsModel.model.length > 0
+            leftPadding: 10
+            rightPadding: 10
+            spacing: 5
+
+            Repeater {
+                id: attachmentsModel
+
+                delegate: AttachmentComponent {
+                    required property int index
+                    required property var modelData
+
+                    itemData: modelData
+                }
+            }
+        }
+
+        Flow {
+            id: imagesFlow
+
+            Layout.fillWidth: true
+            visible: imagesModel.model && imagesModel.model.length > 0
+            leftPadding: 10
+            rightPadding: 10
+            spacing: 10
+
+            Repeater {
+                id: imagesModel
+
+                delegate: ImageComponent {
+                    required property int index
+                    required property var modelData
+
+                    itemData: modelData
+                }
+            }
+        }
+
+        RowLayout {
+            id: usageBadge
+
+            Layout.fillWidth: true
+            Layout.leftMargin: 10
+            Layout.rightMargin: 10
+            spacing: 8
+            visible: !root.isUserMessage
+                     && (root.promptTokens > 0 || root.completionTokens > 0)
+
+            Item { Layout.fillWidth: true }
+
+            Text {
+                text: root.cachedPromptTokens > 0
+                          ? qsTr("↑ %1 (cached %2)").arg(root.promptTokens).arg(root.cachedPromptTokens)
+                          : qsTr("↑ %1").arg(root.promptTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+            Text {
+                text: root.reasoningTokens > 0
+                          ? qsTr("↓ %1 (reasoning %2)").arg(root.completionTokens).arg(root.reasoningTokens)
+                          : qsTr("↓ %1").arg(root.completionTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+            Text {
+                text: qsTr("Σ %1").arg(root.promptTokens + root.completionTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+        }
+    }
+
+    Rectangle {
+        id: userMessageMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: "#92BD6C"
+        radius: root.radius
+        visible: root.isUserMessage
+    }
+
+    QoAButton {
+        id: stopButtonId
+
+        anchors {
+            right: parent.right
+            top: parent.top
+        }
+
+        icon {
+            source: "qrc:/qt/qml/ChatView/icons/undo-changes-button.svg"
+            height: 15
+            width: 15
+        }
+        visible: root.isUserMessage && mouse.hovered
+        onClicked: function() {
+            root.resetChatToMessage(root.messageIndex)
+        }
+
+        QoAToolTip {
+            visible: stopButtonId.hovered
+            text: qsTr("Reset chat to this message and edit")
+            delay: 500
+        }
+    }
+
+    component TextComponent : TextBlock {
+        required property var itemData
+        height: implicitHeight + 10
+        verticalAlignment: Text.AlignVCenter
+        leftPadding: 10
+        text: textFormat == Text.MarkdownText ? utils.getSafeMarkdownText(itemData.text)
+                                              : itemData.text
+        font.family: root.textFontFamily
+        font.pointSize: root.textFontSize
+        textFormat: {
+            if (root.textFormat == 0) {
+                return Text.MarkdownText
+            } else if (root.textFormat == 1) {
+                return Text.RichText
+            } else {
+                return Text.PlainText
+            }
+        }
+
+        onLinkActivated: function(link) {
+            if (link.startsWith("file://")) {
+                var filePath = link.replace(/^file:\/\//, "")
+                root.openFileRequested(filePath)
+            } else {
+                Qt.openUrlExternally(link)
+            }
+        }
+
+        ChatUtils {
+            id: utils
+        }
+    }
+
+    component CodeBlockComponent : CodeBlock {
+        id: codeblock
+
+        required property var itemData
+        anchors {
+            left: parent.left
+            leftMargin: 10
+            right: parent.right
+            rightMargin: 10
+        }
+
+        code: itemData.text
+        language: itemData.language
+        codeFontFamily: root.codeFontFamily
+        codeFontSize: root.codeFontSize
+        viewport: root.chatViewport
+    }
+
+    component AttachmentComponent : Rectangle {
+        required property var itemData
+
+        height: attachFileText.implicitHeight + 8
+        width: attachFileText.implicitWidth + 16
+        radius: 4
+        color: attachFileMouseArea.containsMouse ? Qt.lighter(palette.button, 1.1) : palette.button
+        border.width: 1
+        border.color: palette.mid
+
+        Behavior on color { ColorAnimation { duration: 100 } }
+
+        FileItem {
+            id: fileItem
+            filePath: itemData.filePath || ""
+        }
+
+        Text {
+            id: attachFileText
+
+            anchors.centerIn: parent
+            text: (itemData.fileName || "")
+            color: palette.buttonText
+            font.pointSize: root.textFontSize - 1
+        }
+
+        MouseArea {
+            id: attachFileMouseArea
+
+            anchors.fill: parent
+            hoverEnabled: true
+            acceptedButtons: Qt.LeftButton
+            cursorShape: Qt.PointingHandCursor
+
+            onClicked: (mouse) => {
+                if (mouse.modifiers & Qt.ShiftModifier) {
+                    fileItem.openFileInExternalEditor()
+                } else {
+                    fileItem.openFileInEditor()
+                }
+            }
+
+            QoAToolTip {
+                visible: attachFileMouseArea.containsMouse
+                text: qsTr("Click: Open in Qt Creator\nShift+Click: Open in System Editor")
+                delay: 500
+            }
+        }
+    }
+
+    component ImageComponent : Rectangle {
+        required property var itemData
+
+        readonly property int maxImageWidth: Math.min(400, root.width - 40)
+        readonly property int maxImageHeight: 300
+
+        width: Math.min(imageDisplay.implicitWidth, maxImageWidth) + 16
+        height: imageDisplay.implicitHeight + fileNameText.implicitHeight + 16
+        radius: 4
+        color: imageMouseArea.containsMouse ? Qt.lighter(palette.base, 1.05) : palette.base
+        border.width: 1
+        border.color: palette.mid
+
+        Behavior on color { ColorAnimation { duration: 100 } }
+
+        FileItem {
+            id: imageFileItem
+            filePath: itemData.filePath || ""
+        }
+
+        ColumnLayout {
+            anchors.fill: parent
+            anchors.margins: 8
+            spacing: 4
+
+            Image {
+                id: imageDisplay
+
+                Layout.alignment: Qt.AlignHCenter
+                Layout.maximumWidth: parent.parent.maxImageWidth
+                Layout.maximumHeight: parent.parent.maxImageHeight
+
+                source: itemData.imageUrl ? itemData.imageUrl : ""
+
+                sourceSize.width: parent.parent.maxImageWidth
+                sourceSize.height: parent.parent.maxImageHeight
+                fillMode: Image.PreserveAspectFit
+                cache: true
+                asynchronous: true
+                smooth: true
+                mipmap: true
+
+                QoABusyIndicator {
+                    anchors.centerIn: parent
+                    running: imageDisplay.status === Image.Loading
+                }
+
+                Text {
+                    anchors.centerIn: parent
+                    text: qsTr("Failed to load image")
+                    visible: imageDisplay.status === Image.Error
+                    color: palette.placeholderText
+                }
+            }
+
+            Text {
+                id: fileNameText
+
+                Layout.fillWidth: true
+                text: itemData.fileName || ""
+                color: palette.text
+                font.pointSize: root.textFontSize - 1
+                elide: Text.ElideMiddle
+                horizontalAlignment: Text.AlignHCenter
+            }
+        }
+
+        MouseArea {
+            id: imageMouseArea
+
+            anchors.fill: parent
+            hoverEnabled: true
+            acceptedButtons: Qt.LeftButton
+            cursorShape: Qt.PointingHandCursor
+
+            onClicked: (mouse) => {
+                if (mouse.modifiers & Qt.ShiftModifier) {
+                    imageFileItem.openFileInExternalEditor()
+                } else {
+                    imageFileItem.openFileInEditor()
+                }
+            }
+
+            QoAToolTip {
+                visible: imageMouseArea.containsMouse
+                text: qsTr("Click: Open in Qt Creator\nShift+Click: Open in System Editor")
+                delay: 500
+            }
+        }
+    }
+}

sources/ChatView/qml/chatparts/CodeBlock.qml

@@ -0,0 +1,168 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import ChatView
+import UIControls
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string code: ""
+    property string language: ""
+    property bool expanded: false
+    property Flickable viewport: null
+
+    property alias codeFontFamily: codeText.font.family
+    property alias codeFontSize: codeText.font.pointSize
+    readonly property real collapsedHeight: copyButton.height + 10
+
+    color: palette.alternateBase
+    border.color: root.color.hslLightness > 0.5 ? Qt.darker(root.color, 1.3)
+                                                : Qt.lighter(root.color, 1.3)
+    border.width: 2
+    radius: 4
+    implicitWidth: parent.width
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    ChatUtils {
+        id: utils
+    }
+
+    HoverHandler {
+        id: hoverHandler
+        enabled: true
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: root.collapsedHeight
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            spacing: 6
+
+            Text {
+                text: root.language ? qsTr("Code (%1)").arg(root.language) :
+                                      qsTr("Code")
+                font.pixelSize: 12
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    TextEdit {
+        id: codeText
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        text: root.code
+        readOnly: true
+        selectByMouse: true
+        color: parent.color.hslLightness > 0.5 ? "black" : "white"
+        wrapMode: Text.WordWrap
+        selectionColor: palette.highlight
+
+        MouseArea {
+            anchors.fill: parent
+            acceptedButtons: Qt.RightButton
+            onClicked: contextMenu.open()
+        }
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            onTriggered: {
+                const textToCopy = codeText.selectedText || root.code
+                utils.copyToClipboard(textToCopy)
+            }
+        }
+
+        Platform.MenuSeparator {}
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    QoAButton {
+        id: copyButton
+
+        anchors.right: parent.right
+        anchors.rightMargin: 5
+
+        y: {
+            if (!root.expanded || !root.viewport)
+                return 5
+            const flick = root.viewport
+            const topInContent = root.mapToItem(flick.contentItem, 0, 0).y
+            const topInView = topInContent - flick.contentY
+            const desired = topInView < 0 ? (-topInView + 5) : 5
+            const maxY = Math.max(5, root.height - copyButton.height - 5)
+            return Math.max(5, Math.min(desired, maxY))
+        }
+        text: qsTr("Copy")
+
+        onClicked: {
+            utils.copyToClipboard(root.code)
+            text = qsTr("Copied")
+            copyTimer.start()
+        }
+
+        Timer {
+            id: copyTimer
+            interval: 2000
+            onTriggered: parent.text = qsTr("Copy")
+        }
+    }
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: root.collapsedHeight
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + codeText.implicitHeight + 10
+            }
+        }
+    ]
+}

sources/ChatView/qml/chatparts/FileEditBlock.qml

@@ -0,0 +1,457 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import UIControls
+import ChatView
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string editContent: ""
+
+    readonly property var editData: parseEditData(editContent)
+    readonly property string filePath: editData.file || ""
+    readonly property string fileName: getFileName(filePath)
+    readonly property string editStatus: editData.status || "pending"
+    readonly property string statusMessage: editData.status_message || ""
+    readonly property string oldContent: editData.old_content || ""
+    readonly property string newContent: editData.new_content || ""
+
+    signal applyEdit(string editId)
+    signal rejectEdit(string editId)
+    signal undoEdit(string editId)
+    signal openInEditor(string editId)
+
+    readonly property int borderRadius: 4
+    readonly property int contentMargin: 10
+    readonly property int contentBottomPadding: 20
+    readonly property int headerPadding: 8
+    readonly property int statusIndicatorWidth: 4
+
+    readonly property bool isPending: editStatus === "pending"
+    readonly property bool isApplied: editStatus === "applied"
+    readonly property bool isRejected: editStatus === "rejected"
+    readonly property bool isArchived: editStatus === "archived"
+
+    readonly property color appliedColor: Qt.rgba(0.2, 0.8, 0.2, 0.8)
+    readonly property color revertedColor: Qt.rgba(0.8, 0.6, 0.2, 0.8)
+    readonly property color rejectedColor: Qt.rgba(0.8, 0.2, 0.2, 0.8)
+    readonly property color archivedColor: Qt.rgba(0.5, 0.5, 0.5, 0.8)
+    readonly property color pendingColor: palette.highlight
+
+    readonly property color appliedBgColor: Qt.rgba(0.2, 0.8, 0.2, 0.3)
+    readonly property color revertedBgColor: Qt.rgba(0.8, 0.6, 0.2, 0.3)
+    readonly property color rejectedBgColor: Qt.rgba(0.8, 0.2, 0.2, 0.3)
+    readonly property color archivedBgColor: Qt.rgba(0.5, 0.5, 0.5, 0.3)
+
+    readonly property string codeFontFamily: {
+        switch (Qt.platform.os) {
+        case "windows": return "Consolas"
+        case "osx": return "Menlo"
+        case "linux": return "DejaVu Sans Mono"
+        default: return "monospace"
+        }
+    }
+    readonly property int codeFontSize: Qt.application.font.pointSize
+
+    readonly property color statusColor: {
+        if (isArchived) return archivedColor
+        if (isApplied) return appliedColor
+        if (isRejected) return rejectedColor
+        return pendingColor
+    }
+
+    readonly property color statusBgColor: {
+        if (isArchived) return archivedBgColor
+        if (isApplied) return appliedBgColor
+        if (isRejected) return rejectedBgColor
+        return palette.button
+    }
+
+    readonly property string statusText: {
+        if (isArchived) return qsTr("ARCHIVED")
+        if (isApplied) return qsTr("APPLIED")
+        if (isRejected) return qsTr("REJECTED")
+        return qsTr("PENDING")
+    }
+
+    readonly property int addedLines: countLines(newContent)
+    readonly property int removedLines: countLines(oldContent)
+
+    function parseEditData(content) {
+        try {
+            const marker = "QODEASSIST_FILE_EDIT:";
+            let jsonStr = content;
+            if (content.indexOf(marker) >= 0) {
+                jsonStr = content.substring(content.indexOf(marker) + marker.length);
+            }
+            return JSON.parse(jsonStr);
+        } catch (e) {
+            return {
+                edit_id: "",
+                file: "",
+                old_content: "",
+                new_content: "",
+                status: "error",
+                status_message: ""
+            };
+        }
+    }
+
+    function getFileName(path) {
+        if (!path) return "";
+        const parts = path.split('/');
+        return parts[parts.length - 1];
+    }
+
+    function countLines(text) {
+        if (!text) return 0;
+        return text.split('\n').length;
+    }
+
+    implicitHeight: fileEditView.implicitHeight
+
+    ChatUtils {
+        id: utils
+    }
+
+    Rectangle {
+        id: fileEditView
+
+        property bool expanded: false
+
+        anchors.fill: parent
+        implicitHeight: expanded ? headerArea.height + contentColumn.implicitHeight + root.contentBottomPadding + root.contentMargin * 2
+                                 : headerArea.height
+        radius: root.borderRadius
+
+        color: palette.base
+
+        border.width: 1
+        border.color: root.isPending
+            ? (color.hslLightness > 0.5 ? Qt.darker(color, 1.3) : Qt.lighter(color, 1.3))
+            : Qt.alpha(root.statusColor, 0.6)
+
+        clip: true
+
+        Behavior on implicitHeight {
+            NumberAnimation {
+                duration: 200
+                easing.type: Easing.InOutQuad
+            }
+        }
+
+        states: [
+            State {
+                name: "expanded"
+                when: fileEditView.expanded
+                PropertyChanges { target: contentColumn; opacity: 1 }
+            },
+            State {
+                name: "collapsed"
+                when: !fileEditView.expanded
+                PropertyChanges { target: contentColumn; opacity: 0 }
+            }
+        ]
+
+        transitions: Transition {
+            NumberAnimation {
+                properties: "opacity"
+                duration: 200
+                easing.type: Easing.InOutQuad
+            }
+        }
+
+        MouseArea {
+            id: headerArea
+
+            width: parent.width
+            height: headerRow.height + 16
+            cursorShape: Qt.PointingHandCursor
+            onClicked: fileEditView.expanded = !fileEditView.expanded
+
+            RowLayout {
+                id: headerRow
+
+                anchors {
+                    verticalCenter: parent.verticalCenter
+                    left: parent.left
+                    right: actionButtons.left
+                    leftMargin: root.contentMargin
+                    rightMargin: root.contentMargin
+                }
+                spacing: root.headerPadding
+
+                Rectangle {
+                    width: root.statusIndicatorWidth
+                    height: headerText.height
+                    radius: 2
+                    color: root.statusColor
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/open-in-code.svg"
+                        height: 15
+                        width: 15
+                    }
+                    hoverEnabled: true
+                    onClicked: root.openInEditor(editData.edit_id)
+
+                    QoAToolTip {
+                        visible: parent.hovered
+                        delay: 500
+                        text: qsTr("Open file in editor and navigate to changes")
+                    }
+                }
+
+                Text {
+                    id: headerText
+                    text: {
+                        var modeText = root.oldContent.length > 0 ? qsTr("Replace") : qsTr("Append")
+                        if (root.oldContent.length > 0) {
+                            return qsTr("%1: %2 (+%3 -%4)")
+                                .arg(modeText)
+                                .arg(root.fileName)
+                                .arg(root.addedLines)
+                                .arg(root.removedLines)
+                        } else {
+                            return qsTr("%1: %2 (+%3)")
+                                .arg(modeText)
+                                .arg(root.fileName)
+                                .arg(root.addedLines)
+                        }
+                    }
+                    font.pixelSize: 12
+                    font.bold: true
+                    color: palette.text
+                    elide: Text.ElideMiddle
+                }
+
+                Text {
+                    text: fileEditView.expanded ? "▼" : "▶"
+                    font.pixelSize: 10
+                    color: palette.mid
+                }
+
+                Item { Layout.fillWidth: true }
+            }
+
+            RowLayout {
+                id: actionButtons
+
+                anchors {
+                    right: parent.right
+                    rightMargin: 5
+                    verticalCenter: parent.verticalCenter
+                }
+                spacing: 6
+
+                Rectangle {
+                    visible: !root.isPending
+                    Layout.preferredWidth: badgeText.width + 12
+                    Layout.preferredHeight: badgeText.height + 4
+                    color: root.statusBgColor
+                    radius: 3
+
+                    Text {
+                        id: badgeText
+                        anchors.centerIn: parent
+                        text: root.statusText
+                        font.pixelSize: 9
+                        font.bold: true
+                        color: root.isArchived ? Qt.rgba(0.6, 0.6, 0.6, 1.0) : palette.text
+                    }
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/apply-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }                    enabled: (root.isPending || root.isRejected) && !root.isArchived
+                    visible: !root.isApplied && !root.isArchived
+                    onClicked: root.applyEdit(editData.edit_id)
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/undo-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }
+                    enabled: root.isApplied && !root.isArchived
+                    visible: root.isApplied && !root.isArchived
+                    onClicked: root.undoEdit(editData.edit_id)
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/reject-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }
+                    enabled: root.isPending && !root.isArchived
+                    visible: root.isPending && !root.isArchived
+                    onClicked: root.rejectEdit(editData.edit_id)
+                }
+            }
+        }
+
+        ColumnLayout {
+            id: contentColumn
+
+            anchors {
+                left: parent.left
+                right: parent.right
+                top: headerArea.bottom
+                margins: root.contentMargin
+            }
+            spacing: 8
+            visible: opacity > 0
+
+            Text {
+                Layout.fillWidth: true
+                text: root.filePath
+                font.pixelSize: 10
+                color: palette.mid
+                elide: Text.ElideMiddle
+            }
+
+            Rectangle {
+                Layout.fillWidth: true
+                Layout.preferredHeight: oldContentColumn.implicitHeight + 12
+                color: Qt.rgba(1, 0.2, 0.2, 0.1)
+                radius: 4
+                border.width: 1
+                border.color: Qt.rgba(1, 0.2, 0.2, 0.3)
+                visible: root.oldContent.length > 0
+
+                Column {
+                    id: oldContentColumn
+                    width: parent.width
+                    x: 6
+                    y: 6
+                    spacing: 4
+
+                    TextEdit {
+                        id: oldContentText
+
+                        width: parent.width - 12
+                        height: contentHeight
+                        text: root.oldContent
+                        font.family: root.codeFontFamily
+                        font.pixelSize: root.codeFontSize
+                        color: palette.text
+                        wrapMode: TextEdit.Wrap
+                        readOnly: true
+                        selectByMouse: true
+                        selectByKeyboard: true
+                        textFormat: TextEdit.PlainText
+
+                        MouseArea {
+                            anchors.fill: parent
+                            acceptedButtons: Qt.RightButton
+                            onClicked: oldConentContextMenu.open()
+                        }
+                    }
+
+                    Platform.Menu {
+                        id: oldConentContextMenu
+
+                        Platform.MenuItem {
+                            text: qsTr("Copy")
+                            onTriggered: {
+                                const textToCopy = oldContentText.selectedText || root.oldContent
+                                utils.copyToClipboard(textToCopy)
+                            }
+                        }
+
+                        Platform.MenuSeparator {}
+
+                        Platform.MenuItem {
+                            text: fileEditView.expanded ? qsTr("Collapse") : qsTr("Expand")
+                            onTriggered: fileEditView.expanded = !fileEditView.expanded
+                        }
+                    }
+                }
+            }
+
+            Rectangle {
+                Layout.fillWidth: true
+                Layout.preferredHeight: newContentColumn.implicitHeight + 12
+                color: Qt.rgba(0.2, 0.8, 0.2, 0.1)
+                radius: 4
+                border.width: 1
+                border.color: Qt.rgba(0.2, 0.8, 0.2, 0.3)
+
+                Column {
+                    id: newContentColumn
+
+                    width: parent.width
+                    x: 6
+                    y: 6
+                    spacing: 4
+
+                    TextEdit {
+                        id: newContentText
+
+                        width: parent.width - 12
+                        height: contentHeight
+                        text: root.newContent
+                        font.family: root.codeFontFamily
+                        font.pixelSize: root.codeFontSize
+                        color: palette.text
+                        wrapMode: TextEdit.Wrap
+                        readOnly: true
+                        selectByMouse: true
+                        selectByKeyboard: true
+                        textFormat: TextEdit.PlainText
+
+                        MouseArea {
+                            anchors.fill: parent
+                            acceptedButtons: Qt.RightButton
+                            onClicked: newContentContextMenu.open()
+                        }
+                    }
+
+                    Platform.Menu {
+                        id: newContentContextMenu
+
+                        Platform.MenuItem {
+                            text: qsTr("Copy")
+                            onTriggered: {
+                                const textToCopy = newContentText.selectedText || root.newContent
+                                utils.copyToClipboard(textToCopy)
+                            }
+                        }
+
+                        Platform.MenuSeparator {}
+
+                        Platform.MenuItem {
+                            text: fileEditView.expanded ? qsTr("Collapse") : qsTr("Expand")
+                            onTriggered: fileEditView.expanded = !fileEditView.expanded
+                        }
+                    }
+                }
+            }
+
+            Text {
+                Layout.fillWidth: true
+                visible: root.statusMessage.length > 0
+                text: root.statusMessage
+                font.pixelSize: 10
+                font.italic: true
+                color: root.isApplied
+                    ? Qt.rgba(0.2, 0.6, 0.2, 1)
+                    : Qt.rgba(0.8, 0.2, 0.2, 1)
+                wrapMode: Text.WordWrap
+            }
+        }
+    }
+}

sources/ChatView/qml/chatparts/TextBlock.qml

@@ -0,0 +1,39 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+TextEdit {
+    id: root
+
+    readOnly: true
+    selectByMouse: true
+    wrapMode: Text.WordWrap
+    selectionColor: palette.highlight
+    color: palette.text
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        cursorShape: root.hoveredLink ? Qt.PointingHandCursor : Qt.IBeamCursor
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            enabled: root.selectedText.length > 0
+            onTriggered: root.copy()
+        }
+
+        Platform.MenuItem {
+            text: qsTr("Select All")
+            enabled: root.text.length > 0
+            onTriggered: root.selectAll()
+        }
+    }
+}

sources/ChatView/qml/chatparts/ThinkingBlock.qml

@@ -0,0 +1,168 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string thinkingContent: ""
+    // property string signature: ""
+    property bool isRedacted: false
+    property bool expanded: false
+    
+    property alias headerOpacity: headerRow.opacity
+
+    radius: 6
+    color: palette.base
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: headerRow.height + 10
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            width: parent.width
+            spacing: 8
+
+            Text {
+                text: root.isRedacted ? qsTr("Thinking (Redacted)")
+                                      : qsTr("Thinking")
+                font.pixelSize: 13
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    Column {
+        id: contentColumn
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        spacing: 8
+
+        Text {
+            visible: root.isRedacted
+            width: parent.width
+            text: qsTr("Thinking content was redacted by safety systems")
+            font.pixelSize: 11
+            font.italic: true
+            color: Qt.rgba(0.8, 0.4, 0.4, 1.0)
+            wrapMode: Text.WordWrap
+        }
+
+        TextEdit {
+            id: thinkingText
+
+            visible: !root.isRedacted
+            width: parent.width
+            text: root.thinkingContent
+            readOnly: true
+            selectByMouse: true
+            color: palette.text
+            wrapMode: Text.WordWrap
+            font.family: "monospace"
+            font.pixelSize: 11
+            selectionColor: palette.highlight
+        }
+
+        // Rectangle {
+        //     visible: root.signature.length > 0 && root.expanded
+        //     width: parent.width
+        //     height: signatureText.height + 10
+        //     color: palette.alternateBase
+        //     radius: 4
+
+        //     Text {
+        //         id: signatureText
+
+        //         anchors {
+        //             left: parent.left
+        //             right: parent.right
+        //             verticalCenter: parent.verticalCenter
+        //             margins: 5
+        //         }
+        //         text: qsTr("Signature: %1").arg(root.signature.substring(0, Math.min(40, root.signature.length)) + "...")
+        //         font.pixelSize: 9
+        //         font.family: "monospace"
+        //         color: palette.mid
+        //         elide: Text.ElideRight
+        //     }
+        // }
+    }
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        propagateComposedEvents: true
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    Rectangle {
+        id: thinkingMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: root.isRedacted ? Qt.rgba(0.8, 0.3, 0.3, 0.9)
+                               : (root.color.hslLightness > 0.5 ? Qt.darker(palette.alternateBase, 1.3)
+                                                                : Qt.lighter(palette.alternateBase, 1.3))
+        radius: root.radius
+    }
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + contentColumn.height + 20
+            }
+        }
+    ]
+}
+

sources/ChatView/qml/chatparts/ToolBlock.qml

@@ -0,0 +1,147 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string toolContent: ""
+    property bool expanded: false
+
+    property alias headerOpacity: headerRow.opacity
+
+    readonly property int firstNewline: toolContent.indexOf('\n')
+    readonly property string toolName: firstNewline > 0 ? toolContent.substring(0, firstNewline) : toolContent
+    readonly property string toolResult: firstNewline > 0 ? toolContent.substring(firstNewline + 1) : ""
+
+    radius: 6
+    color: palette.base
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: headerRow.height + 10
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            width: parent.width
+            spacing: 8
+
+            Text {
+                text: qsTr("Tool: %1").arg(root.toolName)
+                font.pixelSize: 13
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    Column {
+        id: contentColumn
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        spacing: 8
+
+        TextEdit {
+            id: resultText
+
+            width: parent.width
+            text: root.toolResult
+            readOnly: true
+            selectByMouse: true
+            color: palette.text
+            wrapMode: Text.WordWrap
+            font.family: "monospace"
+            font.pixelSize: 11
+            selectionColor: palette.highlight
+        }
+    }
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        propagateComposedEvents: true
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            enabled: resultText.selectedText.length > 0
+            onTriggered: resultText.copy()
+        }
+
+        Platform.MenuItem {
+            text: qsTr("Select All")
+            enabled: resultText.text.length > 0
+            onTriggered: resultText.selectAll()
+        }
+
+        Platform.MenuSeparator {}
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    Rectangle {
+        id: messageMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: root.color.hslLightness > 0.5 ? Qt.darker(palette.alternateBase, 1.3)
+                                             : Qt.lighter(palette.alternateBase, 1.3)
+        radius: root.radius
+    }
+
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + contentColumn.height + 20
+            }
+        }
+    ]
+}