refactor: Restructure project into sources/tests layout and dissolve PluginLLMCore

sources/ChatView/qml/RootItem.qml

@@ -0,0 +1,909 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Controls.Basic as QQC
+import QtQuick.Layouts
+import ChatView
+import UIControls
+import Qt.labs.platform as Platform
+
+import "./chatparts"
+import "./controls"
+
+ChatRootView {
+    id: root
+
+    property SystemPalette sysPalette: SystemPalette {
+        colorGroup: SystemPalette.Active
+    }
+
+    property bool hasActiveError: false
+    readonly property color errorColor: "#d32f2f"
+
+    palette {
+        window: sysPalette.window
+        windowText: sysPalette.windowText
+        base: sysPalette.base
+        alternateBase: sysPalette.alternateBase
+        text: sysPalette.text
+        button: sysPalette.button
+        buttonText: sysPalette.buttonText
+        highlight: sysPalette.highlight
+        highlightedText: sysPalette.highlightedText
+        light: sysPalette.light
+        mid: sysPalette.mid
+        dark: sysPalette.dark
+        shadow: sysPalette.shadow
+        brightText: sysPalette.brightText
+    }
+
+    Rectangle {
+        id: bg
+
+        anchors.fill: parent
+        color: palette.window
+    }
+
+    SplitDropZone {
+        anchors.fill: parent
+        z: 99
+
+        onFilesDroppedToAttach: (urlStrings) => {
+            var localPaths = root.convertUrlsToLocalPaths(urlStrings)
+            if (localPaths.length > 0) {
+                root.addFilesToAttachList(localPaths)
+            }
+        }
+
+        onFilesDroppedToLink: (urlStrings) => {
+            var localPaths = root.convertUrlsToLocalPaths(urlStrings)
+            if (localPaths.length > 0) {
+                root.addFilesToLinkList(localPaths)
+            }
+        }
+    }
+
+    QoABusyOverlay {
+        id: compressingOverlay
+
+        z: 50
+
+        anchors.fill: mainColumn
+        anchors.topMargin: topBar.height
+        anchors.bottomMargin: bottomBar.height
+
+        active: root.isCompressing
+        text: qsTr("Compressing chat…")
+    }
+
+    ColumnLayout {
+        id: mainColumn
+
+        anchors.fill: parent
+        spacing: 0
+
+        TopBar {
+            id: topBar
+
+            Layout.preferredWidth: parent.width
+            Layout.preferredHeight: childrenRect.height + 10
+
+            isInEditor: root.isInEditor
+            saveButton.onClicked: root.showSaveDialog()
+            loadButton.onClicked: root.showLoadDialog()
+            clearButton.onClicked: root.clearChat()
+            newChatButton.onClicked: root.requestNewChat()
+            tokensBadge {
+                readonly property int sessionPrompt: root.chatModel.sessionPromptTokens || 0
+                readonly property int sessionCompletion: root.chatModel.sessionCompletionTokens || 0
+                readonly property int sessionCached: root.chatModel.sessionCachedPromptTokens || 0
+                text: sessionCached > 0
+                    ? qsTr("next ~%1  ·  session ↑%2 ↓%3 ↻%4")
+                          .arg(root.inputTokensCount)
+                          .arg(sessionPrompt)
+                          .arg(sessionCompletion)
+                          .arg(sessionCached)
+                    : qsTr("next ~%1  ·  session ↑%2 ↓%3")
+                          .arg(root.inputTokensCount)
+                          .arg(sessionPrompt)
+                          .arg(sessionCompletion)
+                ToolTip.text: sessionCached > 0
+                    ? qsTr("next request (estimate)  ·  session prompt ↑ / completion ↓ / cached ↻ (provider cache hits)")
+                    : qsTr("next request (estimate)  ·  session prompt ↑ / completion ↓")
+            }
+            recentPath {
+                text: qsTr("Сhat name: %1").arg(root.chatFileName.length > 0 ? root.chatFileName : "Unsaved")
+            }
+            openChatHistory.onClicked: root.openChatHistoryFolder()
+            contextButton.onClicked: contextViewer.open()
+            pinButton {
+                visible: typeof _chatview !== 'undefined'
+                checked: typeof _chatview !== 'undefined' ? _chatview.isPin : false
+                onCheckedChanged: _chatview.isPin = topBar.pinButton.checked
+            }
+            relocateButton {
+                icon.source: (typeof _chatview !== 'undefined')
+                             ? "qrc:/qt/qml/ChatView/icons/open-in-editor.svg"
+                             : "qrc:/qt/qml/ChatView/icons/open-in-window.svg"
+                onClicked: {
+                    if (typeof _chatview !== 'undefined')
+                        root.relocateToSplit()
+                    else
+                        root.relocateToWindow()
+                }
+            }
+            relocateTooltip.text: (typeof _chatview !== 'undefined')
+                                   ? qsTr("Move this chat to an editor tab")
+                                   : qsTr("Move this chat to a separate window")
+            toolsButton {
+                checked: root.useTools
+                onCheckedChanged: {
+                    root.useTools = toolsButton.checked
+                }
+            }
+            thinkingMode {
+                checked: root.useThinking
+                enabled: root.isThinkingSupport
+                onCheckedChanged: {
+                    root.useThinking = thinkingMode.checked
+                }
+            }
+            settingsButton.onClicked: root.openSettings()
+            configSelector {
+                model: root.availableConfigurations
+                displayText: root.currentConfiguration
+                onActivated: function(index) {
+                    if (index > 0) {
+                        root.applyConfiguration(root.availableConfigurations[index])
+                    }
+                }
+
+                popup.onAboutToShow: {
+                    root.loadAvailableConfigurations()
+                }
+            }
+
+            roleSelector {
+                model: root.availableAgentRoles
+                displayText: root.currentAgentRole
+                onActivated: function(index) {
+                    root.applyAgentRole(root.availableAgentRoles[index])
+                }
+
+                popup.onAboutToShow: {
+                    root.loadAvailableAgentRoles()
+                }
+            }
+        }
+
+        RowLayout {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            spacing: 2
+
+            MessageNavigator {
+                id: messageNavigator
+
+                Layout.preferredWidth: 16
+                Layout.fillHeight: true
+                Layout.topMargin: 4
+                Layout.bottomMargin: 4
+
+                chatModel: root.chatModel
+
+                onMessageClicked: function(messageIndex) {
+                    chatListView.userScrolledUp = true
+                    chatListView.positionViewAtIndex(messageIndex, ListView.Beginning)
+                }
+            }
+
+        ListView {
+            id: chatListView
+
+            property bool userScrolledUp: false
+
+            function syncNavigatorCurrent() {
+                const top = indexAt(10, contentY + 4)
+                messageNavigator.updateCurrentFromModelIndex(top)
+            }
+
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            leftMargin: 3
+            model: root.chatModel
+            clip: true
+            spacing: 0
+            boundsBehavior: Flickable.StopAtBounds
+            cacheBuffer: 2000
+
+            onContentYChanged: Qt.callLater(syncNavigatorCurrent)
+
+            onMovingChanged: {
+                if (moving) {
+                    userScrolledUp = !atYEnd
+                }
+            }
+
+            onAtYEndChanged: {
+                if (atYEnd) {
+                    userScrolledUp = false
+                }
+            }
+
+            delegate: Loader {
+                id: componentLoader
+
+                required property var model
+                required property int index
+
+                width: ListView.view.width - scroll.width
+
+                sourceComponent: {
+                    if (model.roleType === ChatModel.Tool) {
+                        return toolMessageComponent
+                    } else if (model.roleType === ChatModel.FileEdit) {
+                        return fileEditMessageComponent
+                    } else if (model.roleType === ChatModel.Thinking) {
+                        return thinkingMessageComponent
+                    } else {
+                        return chatItemComponent
+                    }
+                }
+
+            }
+
+            header: Item {
+                width: ListView.view.width - scroll.width
+                height: 30
+            }
+
+            ScrollBar.vertical: QQC.ScrollBar {
+                id: scroll
+            }
+
+            Rectangle {
+                id: scrollToBottomButton
+
+                anchors {
+                    bottom: parent.bottom
+                    horizontalCenter: parent.horizontalCenter
+                    bottomMargin: 10
+                }
+                width: 36
+                height: 36
+                radius: 18
+                color: palette.button
+                border.color: palette.mid
+                border.width: 1
+                visible: chatListView.userScrolledUp
+                opacity: 0.9
+                z: 100
+
+                Text {
+                    anchors.centerIn: parent
+                    text: "▼"
+                    font.pixelSize: 14
+                    color: palette.buttonText
+                }
+
+                MouseArea {
+                    anchors.fill: parent
+                    cursorShape: Qt.PointingHandCursor
+                    onClicked: {
+                        chatListView.userScrolledUp = false
+                        root.scrollToBottom()
+                    }
+                }
+
+                Behavior on visible {
+                    enabled: false
+                }
+            }
+
+            onCountChanged: {
+                if (!userScrolledUp) {
+                    root.scrollToBottom()
+                }
+                Qt.callLater(syncNavigatorCurrent)
+            }
+
+            onContentHeightChanged: {
+                if (!userScrolledUp && atYEnd) {
+                    root.scrollToBottom()
+                }
+            }
+
+            Component {
+                id: chatItemComponent
+
+                ChatItem {
+                    id: chatItemInstance
+
+                    width: parent.width
+                    chatViewport: chatListView
+                    msgModel: root.chatModel.processMessageContent(model.content)
+                    messageAttachments: model.attachments
+                    messageImages: model.images
+                    chatFilePath: root.chatFilePath()
+                    isUserMessage: model.roleType === ChatModel.User
+                    messageIndex: index
+                    textFontFamily: root.textFontFamily
+                    codeFontFamily: root.codeFontFamily
+                    codeFontSize: root.codeFontSize
+                    textFontSize: root.textFontSize
+                    textFormat: root.textFormat
+                    promptTokens: model.promptTokens || 0
+                    completionTokens: model.completionTokens || 0
+                    cachedPromptTokens: model.cachedPromptTokens || 0
+                    reasoningTokens: model.reasoningTokens || 0
+
+                    onResetChatToMessage: function(idx) {
+                        messageInput.text = model.content
+                        messageInput.cursorPosition = model.content.length
+                        root.chatModel.resetModelTo(idx)
+                    }
+
+                    onOpenFileRequested: function(filePath) {
+                        root.openFileInEditor(filePath)
+                    }
+                }
+            }
+
+            Component {
+                id: toolMessageComponent
+
+                ToolBlock {
+                    width: parent.width
+                    toolContent: model.content
+                }
+            }
+
+            Component {
+                id: fileEditMessageComponent
+
+                FileEditBlock {
+                    width: parent.width
+                    editContent: model.content
+
+                    onApplyEdit: function(editId) {
+                        root.applyFileEdit(editId)
+                    }
+
+                    onRejectEdit: function(editId) {
+                        root.rejectFileEdit(editId)
+                    }
+
+                    onUndoEdit: function(editId) {
+                        root.undoFileEdit(editId)
+                    }
+
+                    onOpenInEditor: function(editId) {
+                        root.openFileEditInEditor(editId)
+                    }
+                }
+            }
+
+            Component {
+                id: thinkingMessageComponent
+
+                ThinkingBlock {
+                    width: parent.width
+                    thinkingContent: {
+                        let content = model.content
+                        let signatureStart = content.indexOf("\n[Signature:")
+                        if (signatureStart >= 0) {
+                            return content.substring(0, signatureStart)
+                        }
+                        return content
+                    }
+                    isRedacted: model.isRedacted !== undefined ? model.isRedacted : false
+                }
+            }
+        }
+        }
+
+        ScrollView {
+            id: view
+
+            Layout.fillWidth: true
+            Layout.minimumHeight: 30
+            Layout.maximumHeight: root.height / 2
+
+            QQC.TextArea {
+                id: messageInput
+
+                placeholderText: qsTr("Type your message here... (%1 to send)").arg(root.sendShortcutText)
+                placeholderTextColor: palette.mid
+                color: palette.text
+                wrapMode: TextArea.Wrap
+                background: Rectangle {
+                    radius: 2
+                    color: palette.base
+                    border.color:  messageInput.activeFocus ? palette.highlight : palette.button
+                    border.width: 1
+
+                    Behavior on border.color {
+                        ColorAnimation { duration: 150 }
+                    }
+
+                    Rectangle {
+                        anchors.fill: parent
+                        color: palette.highlight
+                        opacity: messageInput.hovered ? 0.1 : 0
+                        radius: parent.radius
+                    }
+                }
+
+                onTextChanged: {
+                    root.calculateMessageTokensCount(messageInput.text)
+                    var cursorPos = messageInput.cursorPosition
+                    var textBefore = messageInput.text.substring(0, cursorPos)
+
+                    var atIndex = textBefore.lastIndexOf('@')
+                    if (atIndex >= 0) {
+                        var query = textBefore.substring(atIndex + 1)
+                        if (query.indexOf(' ') === -1 && query.indexOf('\n') === -1) {
+                            fileMentionPopup.updateSearch(query)
+                            skillCommandPopup.dismiss()
+                            return
+                        }
+                    }
+                    fileMentionPopup.dismiss()
+
+                    const slashIndex = textBefore.lastIndexOf('/')
+                    if (slashIndex >= 0) {
+                        const beforeSlash = slashIndex === 0
+                                            ? ' '
+                                            : textBefore.charAt(slashIndex - 1)
+                        const skillQuery = textBefore.substring(slashIndex + 1)
+                        if ((beforeSlash === ' ' || beforeSlash === '\n')
+                                && /^[a-z0-9-]*$/.test(skillQuery)) {
+                            skillCommandPopup.updateSearch(skillQuery)
+                            return
+                        }
+                    }
+                    skillCommandPopup.dismiss()
+                }
+
+                Keys.onPressed: function(event) {
+                    if (fileMentionPopup.visible) {
+                        if (event.key === Qt.Key_Down) {
+                            fileMentionPopup.moveDown()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Up) {
+                            fileMentionPopup.moveUp()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Return || event.key === Qt.Key_Enter) {
+                            root.applyMentionSelection()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Escape) {
+                            fileMentionPopup.dismiss()
+                            event.accepted = true
+                        }
+                    } else if (skillCommandPopup.visible) {
+                        if (event.key === Qt.Key_Down) {
+                            skillCommandPopup.moveDown()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Up) {
+                            skillCommandPopup.moveUp()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Return || event.key === Qt.Key_Enter) {
+                            root.applySkillSelection()
+                            event.accepted = true
+                        } else if (event.key === Qt.Key_Escape) {
+                            skillCommandPopup.dismiss()
+                            event.accepted = true
+                        }
+                    } else if (root.isSendShortcut(event.key, event.modifiers)) {
+                        root.sendChatMessage()
+                        event.accepted = true
+                    }
+                }
+
+                MouseArea {
+                    anchors.fill: parent
+                    acceptedButtons: Qt.RightButton
+                    onClicked: messageContextMenu.open()
+                    propagateComposedEvents: true
+                }
+            }
+        }
+
+        Platform.Menu {
+            id: messageContextMenu
+
+            Platform.MenuItem {
+                text: qsTr("Cut")
+                enabled: messageInput.selectedText.length > 0
+                onTriggered: messageInput.cut()
+            }
+
+            Platform.MenuItem {
+                text: qsTr("Copy")
+                enabled: messageInput.selectedText.length > 0
+                onTriggered: messageInput.copy()
+            }
+
+            Platform.MenuItem {
+                text: qsTr("Paste")
+                enabled: messageInput.canPaste
+                onTriggered: messageInput.paste()
+            }
+
+            Platform.MenuSeparator {}
+
+            Platform.MenuItem {
+                text: qsTr("Select All")
+                enabled: messageInput.text.length > 0
+                onTriggered: messageInput.selectAll()
+            }
+
+            Platform.MenuSeparator {}
+
+            Platform.MenuItem {
+                text: qsTr("Clear")
+                enabled: messageInput.text.length > 0
+                onTriggered: messageInput.clear()
+            }
+        }
+
+        AttachedFilesPlace {
+            id: attachedFilesPlace
+
+            Layout.fillWidth: true
+            attachedFilesModel: root.attachmentFiles
+            iconPath: palette.window.hslLightness > 0.5 ? "qrc:/qt/qml/ChatView/icons/attach-file-dark.svg"
+                                                        : "qrc:/qt/qml/ChatView/icons/attach-file-light.svg"
+            accentColor: Qt.tint(palette.mid, Qt.rgba(0, 0.8, 0.3, 0.4))
+            onRemoveFileFromListByIndex: (index) => root.removeFileFromAttachList(index)
+        }
+
+        AttachedFilesPlace {
+            id: linkedFilesPlace
+
+            Layout.fillWidth: true
+            attachedFilesModel: root.linkedFiles
+            iconPath: palette.window.hslLightness > 0.5 ? "qrc:/qt/qml/ChatView/icons/link-file-dark.svg"
+                                                        : "qrc:/qt/qml/ChatView/icons/link-file-light.svg"
+            accentColor: Qt.tint(palette.mid, Qt.rgba(0, 0.3, 0.8, 0.4))
+            onRemoveFileFromListByIndex: (index) => root.removeFileFromLinkList(index)
+        }
+
+        FileEditsActionBar {
+            id: fileEditsActionBar
+
+            Layout.fillWidth: true
+            totalEdits: root.currentMessageTotalEdits
+            appliedEdits: root.currentMessageAppliedEdits
+            pendingEdits: root.currentMessagePendingEdits
+            rejectedEdits: root.currentMessageRejectedEdits
+
+            onApplyAllClicked: root.applyAllFileEditsForCurrentMessage()
+            onUndoAllClicked: root.undoAllFileEditsForCurrentMessage()
+        }
+
+        BottomBar {
+            id: bottomBar
+
+            Layout.preferredWidth: parent.width
+            Layout.preferredHeight: 40
+
+            isCompressing: root.isCompressing
+            isProcessing: root.isRequestInProgress
+            sendButton.onClicked: !root.isRequestInProgress ? root.sendChatMessage()
+                                                            : root.cancelRequest()
+            sendButton.icon.source: root.isRequestInProgress
+                                    ? ""
+                                    : (root.hasActiveError ? "qrc:/qt/qml/ChatView/icons/warning-icon.svg"
+                                                           : "qrc:/qt/qml/ChatView/icons/chat-icon.svg")
+            sendButton.text: root.isRequestInProgress ? qsTr("Stop") : qsTr("Send")
+            sendButton.accentColor: (root.hasActiveError && !root.isRequestInProgress)
+                                    ? root.errorColor : "transparent"
+            sendButtonTooltip.text: root.isRequestInProgress
+                                    ? qsTr("Stop")
+                                    : (root.hasActiveError
+                                       ? root.lastErrorMessage
+                                       : qsTr("Send message to LLM %1").arg(root.sendShortcutText))
+            compressButton.onClicked: compressConfirmDialog.open()
+            cancelCompressButton.onClicked: root.cancelCompression()
+            syncOpenFiles {
+                checked: root.isSyncOpenFiles
+                onCheckedChanged: root.setIsSyncOpenFiles(bottomBar.syncOpenFiles.checked)
+            }
+            attachFiles.onClicked: root.showAttachFilesDialog()
+            attachImages.onClicked: root.showAddImageDialog()
+            linkFiles.onClicked: root.showLinkFilesDialog()
+        }
+    }
+
+    function clearChat() {
+        root.clearMessages()
+        root.clearAttachmentFiles()
+        root.updateInputTokensCount()
+    }
+
+    function scrollToBottom() {
+        Qt.callLater(chatListView.positionViewAtEnd)
+    }
+
+    function focusInput() {
+        messageInput.forceActiveFocus()
+    }
+
+    property Item focusGuard: Window.activeFocusItem
+    onFocusGuardChanged: Qt.callLater(returnFocusToInputIfNeeded)
+
+    function returnFocusToInputIfNeeded() {
+        var item = Window.activeFocusItem
+        if (!item || item === messageInput)
+            return
+        if (item.cursorVisible !== undefined || item.selectByMouse !== undefined)
+            return
+        if (item.popup !== undefined)
+            return
+        var p = item
+        while (p) {
+            if (p === root) {
+                messageInput.forceActiveFocus()
+                return
+            }
+            p = p.parent
+        }
+    }
+
+    function applyMentionSelection() {
+        var result = fileMentionPopup.applyCurrentSelection(
+            messageInput.text, messageInput.cursorPosition, root.useTools)
+        if (result.text !== undefined) {
+            messageInput.text = result.text
+            messageInput.cursorPosition = result.cursorPosition
+        }
+    }
+
+    function applySkillSelection() {
+        const name = skillCommandPopup.currentName()
+        if (name === "")
+            return
+        const cursorPos = messageInput.cursorPosition
+        const textBefore = messageInput.text.substring(0, cursorPos)
+        const slashIndex = textBefore.lastIndexOf('/')
+        if (slashIndex < 0)
+            return
+        const before = messageInput.text.substring(0, slashIndex)
+        const after = messageInput.text.substring(cursorPos)
+        const token = '/' + name + ' '
+        messageInput.text = before + token + after
+        messageInput.cursorPosition = before.length + token.length
+        skillCommandPopup.dismiss()
+    }
+
+    function sendChatMessage() {
+        root.hasActiveError = false
+        root.sendMessage(fileMentionPopup.expandMentions(messageInput.text))
+        messageInput.text = ""
+        fileMentionPopup.clearMentions()
+        scrollToBottom()
+    }
+
+    Dialog {
+        id: compressConfirmDialog
+
+        anchors.centerIn: parent
+        title: qsTr("Compress Chat")
+        modal: true
+        standardButtons: Dialog.Yes | Dialog.No
+
+        Label {
+            text: qsTr("Create a summarized copy of this chat?\n\nThe summary will be generated by LLM and saved as a new chat file.")
+            wrapMode: Text.WordWrap
+        }
+
+        onAccepted: root.compressCurrentChat()
+    }
+
+    Rectangle {
+        id: errorBanner
+
+        z: 1000
+        visible: root.hasActiveError && root.lastErrorMessage.length > 0
+
+        width: parent.width / 2
+        anchors.right: parent.right
+        anchors.bottom: parent.bottom
+        anchors.rightMargin: 10
+        anchors.bottomMargin: bottomBar.height + 48
+
+        height: visible ? errorRow.implicitHeight + 12 : 0
+
+        color: Qt.rgba(0.83, 0.18, 0.18, 0.96)
+        radius: 6
+        border.color: Qt.darker(color, 1.3)
+        border.width: 1
+
+        RowLayout {
+            id: errorRow
+
+            anchors.left: parent.left
+            anchors.right: parent.right
+            anchors.verticalCenter: parent.verticalCenter
+            anchors.leftMargin: 10
+            anchors.rightMargin: 6
+            spacing: 8
+
+            TextEdit {
+                Layout.fillWidth: true
+                text: root.lastErrorMessage
+                color: "#FFFFFF"
+                font.pixelSize: 12
+                wrapMode: TextEdit.Wrap
+                readOnly: true
+                selectByMouse: true
+                selectionColor: Qt.darker(errorBanner.color, 1.3)
+            }
+
+            Rectangle {
+                id: copyErrorButton
+
+                property bool copied: false
+
+                Layout.alignment: Qt.AlignTop
+                implicitWidth: copyErrorLabel.implicitWidth + 18
+                implicitHeight: 22
+                radius: 4
+                color: copyErrorMouse.containsMouse ? Qt.rgba(1, 1, 1, 0.28)
+                                                    : Qt.rgba(1, 1, 1, 0.16)
+                border.color: Qt.rgba(1, 1, 1, 0.45)
+                border.width: 1
+
+                Behavior on color { ColorAnimation { duration: 120 } }
+
+                Text {
+                    id: copyErrorLabel
+
+                    anchors.centerIn: parent
+                    text: copyErrorButton.copied ? qsTr("Copied") : qsTr("Copy")
+                    color: "#FFFFFF"
+                    font.pixelSize: 12
+                }
+
+                MouseArea {
+                    id: copyErrorMouse
+
+                    anchors.fill: parent
+                    hoverEnabled: true
+                    cursorShape: Qt.PointingHandCursor
+                    onClicked: {
+                        root.copyToClipboard(root.lastErrorMessage)
+                        copyErrorButton.copied = true
+                        copyErrorResetTimer.restart()
+                    }
+                }
+
+                Timer {
+                    id: copyErrorResetTimer
+
+                    interval: 1500
+                    onTriggered: copyErrorButton.copied = false
+                }
+            }
+
+            Rectangle {
+                id: closeErrorButton
+
+                Layout.alignment: Qt.AlignTop
+                implicitWidth: 22
+                implicitHeight: 22
+                radius: 4
+                color: closeErrorMouse.containsMouse ? Qt.rgba(1, 1, 1, 0.28) : "transparent"
+                border.color: Qt.rgba(1, 1, 1, 0.45)
+                border.width: closeErrorMouse.containsMouse ? 1 : 0
+
+                Behavior on color { ColorAnimation { duration: 120 } }
+
+                Text {
+                    anchors.centerIn: parent
+                    text: "✕"
+                    color: "#FFFFFF"
+                    font.pixelSize: 12
+                }
+
+                MouseArea {
+                    id: closeErrorMouse
+
+                    anchors.fill: parent
+                    hoverEnabled: true
+                    cursorShape: Qt.PointingHandCursor
+                    onClicked: root.hasActiveError = false
+                }
+            }
+        }
+    }
+
+    Toast {
+        id: infoToast
+        z: 1000
+
+        color: Qt.rgba(0.2, 0.8, 0.2, 0.9)
+        border.color: Qt.darker(infoToast.color, 1.3)
+        toastTextColor: "#FFFFFF"
+    }
+
+    ContextViewer {
+        id: contextViewer
+
+        width: Math.min(parent.width * 0.85, 800)
+        height: Math.min(parent.height * 0.85, 700)
+        x: (parent.width - width) / 2
+        y: (parent.height - height) / 2
+
+        baseSystemPrompt: root.baseSystemPrompt
+        currentAgentRole: root.currentAgentRole
+        currentAgentRoleDescription: root.currentAgentRoleDescription
+        currentAgentRoleSystemPrompt: root.currentAgentRoleSystemPrompt
+        activeRules: root.activeRules
+        activeRulesCount: root.activeRulesCount
+
+        onOpenSettings: root.openSettings()
+        onOpenAgentRolesSettings: root.openAgentRolesSettings()
+        onOpenRulesFolder: root.openRulesFolder()
+        onRefreshRules: root.refreshRules()
+        onRuleSelected: function(index) {
+            contextViewer.selectedRuleContent = root.getRuleContent(index)
+        }
+    }
+
+    Connections {
+        target: root
+        function onLastErrorMessageChanged() {
+            if (root.lastErrorMessage.length > 0) {
+                root.hasActiveError = true
+            }
+        }
+        function onLastInfoMessageChanged() {
+            if (root.lastInfoMessage.length > 0) {
+                infoToast.show(root.lastInfoMessage)
+            }
+        }
+        function onOpenFilesChanged() {
+            if (fileMentionPopup.visible)
+                Qt.callLater(fileMentionPopup.refreshSearch)
+        }
+    }
+
+    FileMentionPopup {
+        id: fileMentionPopup
+
+        z: 999
+        width: Math.min(480, root.width - 20)
+
+        x: Math.max(5, Math.min(view.x + 5, root.width - width - 5))
+        y: view.y - height - 4
+
+        onSelectionRequested: root.applyMentionSelection()
+
+        onFileAttachRequested: function(filePaths) {
+            root.addFilesToAttachList(filePaths)
+        }
+    }
+
+    SkillCommandPopup {
+        id: skillCommandPopup
+
+        z: 999
+        width: Math.min(480, root.width - 20)
+
+        x: Math.max(5, Math.min(view.x + 5, root.width - width - 5))
+        y: view.y - height - 4
+
+        skillProvider: root
+
+        onSelectionRequested: root.applySkillSelection()
+    }
+
+    Component.onCompleted: {
+        focusInput()
+    }
+}

sources/ChatView/qml/chatparts/ChatItem.qml

@@ -0,0 +1,407 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import ChatView
+import QtQuick.Controls
+import QtQuick.Layouts
+import UIControls
+
+Rectangle {
+    id: root
+
+    property alias msgModel: msgCreator.model
+    property alias messageAttachments: attachmentsModel.model
+    property alias messageImages: imagesModel.model
+    property string chatFilePath: ""
+    property string textFontFamily: Qt.application.font.family
+    property string codeFontFamily: {
+        switch (Qt.platform.os) {
+        case "windows":
+            return "Consolas";
+        case "osx":
+            return "Menlo";
+        case "linux":
+            return "DejaVu Sans Mono";
+        default:
+            return "monospace";
+        }
+    }
+    property int textFontSize: Qt.application.font.pointSize
+    property int codeFontSize: Qt.application.font.pointSize
+    property int textFormat: 0
+    property Flickable chatViewport: null
+
+    property bool isUserMessage: false
+    property int messageIndex: -1
+
+    property int promptTokens: 0
+    property int completionTokens: 0
+    property int cachedPromptTokens: 0
+    property int reasoningTokens: 0
+
+    signal resetChatToMessage(int index)
+    signal openFileRequested(string filePath)
+
+    height: msgColumn.implicitHeight + 10
+    radius: 8
+    color: isUserMessage ? palette.alternateBase
+                         : palette.base
+
+    HoverHandler {
+        id: mouse
+    }
+
+    ColumnLayout {
+        id: msgColumn
+
+        x: 5
+        width: parent.width - x
+        anchors.verticalCenter: parent.verticalCenter
+        spacing: 5
+
+        Repeater {
+            id: msgCreator
+            delegate: Loader {
+                id: msgCreatorDelegate
+                // Fix me:
+                // why does `required property MessagePart modelData` not work?
+                required property var modelData
+
+                Layout.preferredWidth: root.width
+                sourceComponent: {
+                    // If `required property MessagePart modelData` is used
+                    // and conversion to MessagePart fails, you're left
+                    // with a nullptr. This tests that to prevent crashing.
+                    if(!modelData) {
+                        return undefined;
+                    }
+
+                    switch(modelData.type) {
+                        case MessagePartType.Text: return textComponent;
+                        case MessagePartType.Code: return codeBlockComponent;
+                        default: return textComponent;
+                    }
+                }
+
+                Component {
+                    id: textComponent
+                    TextComponent {
+                        itemData: msgCreatorDelegate.modelData
+                    }
+                }
+
+                Component {
+                    id: codeBlockComponent
+                    CodeBlockComponent {
+                        itemData: msgCreatorDelegate.modelData
+                    }
+                }
+            }
+        }
+
+        Flow {
+            id: attachmentsFlow
+
+            Layout.fillWidth: true
+            visible: attachmentsModel.model && attachmentsModel.model.length > 0
+            leftPadding: 10
+            rightPadding: 10
+            spacing: 5
+
+            Repeater {
+                id: attachmentsModel
+
+                delegate: AttachmentComponent {
+                    required property int index
+                    required property var modelData
+
+                    itemData: modelData
+                }
+            }
+        }
+
+        Flow {
+            id: imagesFlow
+
+            Layout.fillWidth: true
+            visible: imagesModel.model && imagesModel.model.length > 0
+            leftPadding: 10
+            rightPadding: 10
+            spacing: 10
+
+            Repeater {
+                id: imagesModel
+
+                delegate: ImageComponent {
+                    required property int index
+                    required property var modelData
+
+                    itemData: modelData
+                }
+            }
+        }
+
+        RowLayout {
+            id: usageBadge
+
+            Layout.fillWidth: true
+            Layout.leftMargin: 10
+            Layout.rightMargin: 10
+            spacing: 8
+            visible: !root.isUserMessage
+                     && (root.promptTokens > 0 || root.completionTokens > 0)
+
+            Item { Layout.fillWidth: true }
+
+            Text {
+                text: root.cachedPromptTokens > 0
+                          ? qsTr("↑ %1 (cached %2)").arg(root.promptTokens).arg(root.cachedPromptTokens)
+                          : qsTr("↑ %1").arg(root.promptTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+            Text {
+                text: root.reasoningTokens > 0
+                          ? qsTr("↓ %1 (reasoning %2)").arg(root.completionTokens).arg(root.reasoningTokens)
+                          : qsTr("↓ %1").arg(root.completionTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+            Text {
+                text: qsTr("Σ %1").arg(root.promptTokens + root.completionTokens)
+                color: palette.placeholderText
+                font.pointSize: Math.max(root.textFontSize - 2, 7)
+            }
+        }
+    }
+
+    Rectangle {
+        id: userMessageMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: "#92BD6C"
+        radius: root.radius
+        visible: root.isUserMessage
+    }
+
+    QoAButton {
+        id: stopButtonId
+
+        anchors {
+            right: parent.right
+            top: parent.top
+        }
+
+        icon {
+            source: "qrc:/qt/qml/ChatView/icons/undo-changes-button.svg"
+            height: 15
+            width: 15
+        }
+        visible: root.isUserMessage && mouse.hovered
+        onClicked: function() {
+            root.resetChatToMessage(root.messageIndex)
+        }
+
+        QoAToolTip {
+            visible: stopButtonId.hovered
+            text: qsTr("Reset chat to this message and edit")
+            delay: 500
+        }
+    }
+
+    component TextComponent : TextBlock {
+        required property var itemData
+        height: implicitHeight + 10
+        verticalAlignment: Text.AlignVCenter
+        leftPadding: 10
+        text: textFormat == Text.MarkdownText ? utils.getSafeMarkdownText(itemData.text)
+                                              : itemData.text
+        font.family: root.textFontFamily
+        font.pointSize: root.textFontSize
+        textFormat: {
+            if (root.textFormat == 0) {
+                return Text.MarkdownText
+            } else if (root.textFormat == 1) {
+                return Text.RichText
+            } else {
+                return Text.PlainText
+            }
+        }
+
+        onLinkActivated: function(link) {
+            if (link.startsWith("file://")) {
+                var filePath = link.replace(/^file:\/\//, "")
+                root.openFileRequested(filePath)
+            } else {
+                Qt.openUrlExternally(link)
+            }
+        }
+
+        ChatUtils {
+            id: utils
+        }
+    }
+
+    component CodeBlockComponent : CodeBlock {
+        id: codeblock
+
+        required property var itemData
+        anchors {
+            left: parent.left
+            leftMargin: 10
+            right: parent.right
+            rightMargin: 10
+        }
+
+        code: itemData.text
+        language: itemData.language
+        codeFontFamily: root.codeFontFamily
+        codeFontSize: root.codeFontSize
+        viewport: root.chatViewport
+    }
+
+    component AttachmentComponent : Rectangle {
+        required property var itemData
+
+        height: attachFileText.implicitHeight + 8
+        width: attachFileText.implicitWidth + 16
+        radius: 4
+        color: attachFileMouseArea.containsMouse ? Qt.lighter(palette.button, 1.1) : palette.button
+        border.width: 1
+        border.color: palette.mid
+
+        Behavior on color { ColorAnimation { duration: 100 } }
+
+        FileItem {
+            id: fileItem
+            filePath: itemData.filePath || ""
+        }
+
+        Text {
+            id: attachFileText
+
+            anchors.centerIn: parent
+            text: (itemData.fileName || "")
+            color: palette.buttonText
+            font.pointSize: root.textFontSize - 1
+        }
+
+        MouseArea {
+            id: attachFileMouseArea
+
+            anchors.fill: parent
+            hoverEnabled: true
+            acceptedButtons: Qt.LeftButton
+            cursorShape: Qt.PointingHandCursor
+
+            onClicked: (mouse) => {
+                if (mouse.modifiers & Qt.ShiftModifier) {
+                    fileItem.openFileInExternalEditor()
+                } else {
+                    fileItem.openFileInEditor()
+                }
+            }
+
+            QoAToolTip {
+                visible: attachFileMouseArea.containsMouse
+                text: qsTr("Click: Open in Qt Creator\nShift+Click: Open in System Editor")
+                delay: 500
+            }
+        }
+    }
+
+    component ImageComponent : Rectangle {
+        required property var itemData
+
+        readonly property int maxImageWidth: Math.min(400, root.width - 40)
+        readonly property int maxImageHeight: 300
+
+        width: Math.min(imageDisplay.implicitWidth, maxImageWidth) + 16
+        height: imageDisplay.implicitHeight + fileNameText.implicitHeight + 16
+        radius: 4
+        color: imageMouseArea.containsMouse ? Qt.lighter(palette.base, 1.05) : palette.base
+        border.width: 1
+        border.color: palette.mid
+
+        Behavior on color { ColorAnimation { duration: 100 } }
+
+        FileItem {
+            id: imageFileItem
+            filePath: itemData.filePath || ""
+        }
+
+        ColumnLayout {
+            anchors.fill: parent
+            anchors.margins: 8
+            spacing: 4
+
+            Image {
+                id: imageDisplay
+
+                Layout.alignment: Qt.AlignHCenter
+                Layout.maximumWidth: parent.parent.maxImageWidth
+                Layout.maximumHeight: parent.parent.maxImageHeight
+
+                source: itemData.imageUrl ? itemData.imageUrl : ""
+
+                sourceSize.width: parent.parent.maxImageWidth
+                sourceSize.height: parent.parent.maxImageHeight
+                fillMode: Image.PreserveAspectFit
+                cache: true
+                asynchronous: true
+                smooth: true
+                mipmap: true
+
+                QoABusyIndicator {
+                    anchors.centerIn: parent
+                    running: imageDisplay.status === Image.Loading
+                }
+
+                Text {
+                    anchors.centerIn: parent
+                    text: qsTr("Failed to load image")
+                    visible: imageDisplay.status === Image.Error
+                    color: palette.placeholderText
+                }
+            }
+
+            Text {
+                id: fileNameText
+
+                Layout.fillWidth: true
+                text: itemData.fileName || ""
+                color: palette.text
+                font.pointSize: root.textFontSize - 1
+                elide: Text.ElideMiddle
+                horizontalAlignment: Text.AlignHCenter
+            }
+        }
+
+        MouseArea {
+            id: imageMouseArea
+
+            anchors.fill: parent
+            hoverEnabled: true
+            acceptedButtons: Qt.LeftButton
+            cursorShape: Qt.PointingHandCursor
+
+            onClicked: (mouse) => {
+                if (mouse.modifiers & Qt.ShiftModifier) {
+                    imageFileItem.openFileInExternalEditor()
+                } else {
+                    imageFileItem.openFileInEditor()
+                }
+            }
+
+            QoAToolTip {
+                visible: imageMouseArea.containsMouse
+                text: qsTr("Click: Open in Qt Creator\nShift+Click: Open in System Editor")
+                delay: 500
+            }
+        }
+    }
+}

sources/ChatView/qml/chatparts/CodeBlock.qml

@@ -0,0 +1,168 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import ChatView
+import UIControls
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string code: ""
+    property string language: ""
+    property bool expanded: false
+    property Flickable viewport: null
+
+    property alias codeFontFamily: codeText.font.family
+    property alias codeFontSize: codeText.font.pointSize
+    readonly property real collapsedHeight: copyButton.height + 10
+
+    color: palette.alternateBase
+    border.color: root.color.hslLightness > 0.5 ? Qt.darker(root.color, 1.3)
+                                                : Qt.lighter(root.color, 1.3)
+    border.width: 2
+    radius: 4
+    implicitWidth: parent.width
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    ChatUtils {
+        id: utils
+    }
+
+    HoverHandler {
+        id: hoverHandler
+        enabled: true
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: root.collapsedHeight
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            spacing: 6
+
+            Text {
+                text: root.language ? qsTr("Code (%1)").arg(root.language) :
+                                      qsTr("Code")
+                font.pixelSize: 12
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    TextEdit {
+        id: codeText
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        text: root.code
+        readOnly: true
+        selectByMouse: true
+        color: parent.color.hslLightness > 0.5 ? "black" : "white"
+        wrapMode: Text.WordWrap
+        selectionColor: palette.highlight
+
+        MouseArea {
+            anchors.fill: parent
+            acceptedButtons: Qt.RightButton
+            onClicked: contextMenu.open()
+        }
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            onTriggered: {
+                const textToCopy = codeText.selectedText || root.code
+                utils.copyToClipboard(textToCopy)
+            }
+        }
+
+        Platform.MenuSeparator {}
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    QoAButton {
+        id: copyButton
+
+        anchors.right: parent.right
+        anchors.rightMargin: 5
+
+        y: {
+            if (!root.expanded || !root.viewport)
+                return 5
+            const flick = root.viewport
+            const topInContent = root.mapToItem(flick.contentItem, 0, 0).y
+            const topInView = topInContent - flick.contentY
+            const desired = topInView < 0 ? (-topInView + 5) : 5
+            const maxY = Math.max(5, root.height - copyButton.height - 5)
+            return Math.max(5, Math.min(desired, maxY))
+        }
+        text: qsTr("Copy")
+
+        onClicked: {
+            utils.copyToClipboard(root.code)
+            text = qsTr("Copied")
+            copyTimer.start()
+        }
+
+        Timer {
+            id: copyTimer
+            interval: 2000
+            onTriggered: parent.text = qsTr("Copy")
+        }
+    }
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: root.collapsedHeight
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + codeText.implicitHeight + 10
+            }
+        }
+    ]
+}

sources/ChatView/qml/chatparts/FileEditBlock.qml

@@ -0,0 +1,457 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import UIControls
+import ChatView
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string editContent: ""
+
+    readonly property var editData: parseEditData(editContent)
+    readonly property string filePath: editData.file || ""
+    readonly property string fileName: getFileName(filePath)
+    readonly property string editStatus: editData.status || "pending"
+    readonly property string statusMessage: editData.status_message || ""
+    readonly property string oldContent: editData.old_content || ""
+    readonly property string newContent: editData.new_content || ""
+
+    signal applyEdit(string editId)
+    signal rejectEdit(string editId)
+    signal undoEdit(string editId)
+    signal openInEditor(string editId)
+
+    readonly property int borderRadius: 4
+    readonly property int contentMargin: 10
+    readonly property int contentBottomPadding: 20
+    readonly property int headerPadding: 8
+    readonly property int statusIndicatorWidth: 4
+
+    readonly property bool isPending: editStatus === "pending"
+    readonly property bool isApplied: editStatus === "applied"
+    readonly property bool isRejected: editStatus === "rejected"
+    readonly property bool isArchived: editStatus === "archived"
+
+    readonly property color appliedColor: Qt.rgba(0.2, 0.8, 0.2, 0.8)
+    readonly property color revertedColor: Qt.rgba(0.8, 0.6, 0.2, 0.8)
+    readonly property color rejectedColor: Qt.rgba(0.8, 0.2, 0.2, 0.8)
+    readonly property color archivedColor: Qt.rgba(0.5, 0.5, 0.5, 0.8)
+    readonly property color pendingColor: palette.highlight
+
+    readonly property color appliedBgColor: Qt.rgba(0.2, 0.8, 0.2, 0.3)
+    readonly property color revertedBgColor: Qt.rgba(0.8, 0.6, 0.2, 0.3)
+    readonly property color rejectedBgColor: Qt.rgba(0.8, 0.2, 0.2, 0.3)
+    readonly property color archivedBgColor: Qt.rgba(0.5, 0.5, 0.5, 0.3)
+
+    readonly property string codeFontFamily: {
+        switch (Qt.platform.os) {
+        case "windows": return "Consolas"
+        case "osx": return "Menlo"
+        case "linux": return "DejaVu Sans Mono"
+        default: return "monospace"
+        }
+    }
+    readonly property int codeFontSize: Qt.application.font.pointSize
+
+    readonly property color statusColor: {
+        if (isArchived) return archivedColor
+        if (isApplied) return appliedColor
+        if (isRejected) return rejectedColor
+        return pendingColor
+    }
+
+    readonly property color statusBgColor: {
+        if (isArchived) return archivedBgColor
+        if (isApplied) return appliedBgColor
+        if (isRejected) return rejectedBgColor
+        return palette.button
+    }
+
+    readonly property string statusText: {
+        if (isArchived) return qsTr("ARCHIVED")
+        if (isApplied) return qsTr("APPLIED")
+        if (isRejected) return qsTr("REJECTED")
+        return qsTr("PENDING")
+    }
+
+    readonly property int addedLines: countLines(newContent)
+    readonly property int removedLines: countLines(oldContent)
+
+    function parseEditData(content) {
+        try {
+            const marker = "QODEASSIST_FILE_EDIT:";
+            let jsonStr = content;
+            if (content.indexOf(marker) >= 0) {
+                jsonStr = content.substring(content.indexOf(marker) + marker.length);
+            }
+            return JSON.parse(jsonStr);
+        } catch (e) {
+            return {
+                edit_id: "",
+                file: "",
+                old_content: "",
+                new_content: "",
+                status: "error",
+                status_message: ""
+            };
+        }
+    }
+
+    function getFileName(path) {
+        if (!path) return "";
+        const parts = path.split('/');
+        return parts[parts.length - 1];
+    }
+
+    function countLines(text) {
+        if (!text) return 0;
+        return text.split('\n').length;
+    }
+
+    implicitHeight: fileEditView.implicitHeight
+
+    ChatUtils {
+        id: utils
+    }
+
+    Rectangle {
+        id: fileEditView
+
+        property bool expanded: false
+
+        anchors.fill: parent
+        implicitHeight: expanded ? headerArea.height + contentColumn.implicitHeight + root.contentBottomPadding + root.contentMargin * 2
+                                 : headerArea.height
+        radius: root.borderRadius
+
+        color: palette.base
+
+        border.width: 1
+        border.color: root.isPending
+            ? (color.hslLightness > 0.5 ? Qt.darker(color, 1.3) : Qt.lighter(color, 1.3))
+            : Qt.alpha(root.statusColor, 0.6)
+
+        clip: true
+
+        Behavior on implicitHeight {
+            NumberAnimation {
+                duration: 200
+                easing.type: Easing.InOutQuad
+            }
+        }
+
+        states: [
+            State {
+                name: "expanded"
+                when: fileEditView.expanded
+                PropertyChanges { target: contentColumn; opacity: 1 }
+            },
+            State {
+                name: "collapsed"
+                when: !fileEditView.expanded
+                PropertyChanges { target: contentColumn; opacity: 0 }
+            }
+        ]
+
+        transitions: Transition {
+            NumberAnimation {
+                properties: "opacity"
+                duration: 200
+                easing.type: Easing.InOutQuad
+            }
+        }
+
+        MouseArea {
+            id: headerArea
+
+            width: parent.width
+            height: headerRow.height + 16
+            cursorShape: Qt.PointingHandCursor
+            onClicked: fileEditView.expanded = !fileEditView.expanded
+
+            RowLayout {
+                id: headerRow
+
+                anchors {
+                    verticalCenter: parent.verticalCenter
+                    left: parent.left
+                    right: actionButtons.left
+                    leftMargin: root.contentMargin
+                    rightMargin: root.contentMargin
+                }
+                spacing: root.headerPadding
+
+                Rectangle {
+                    width: root.statusIndicatorWidth
+                    height: headerText.height
+                    radius: 2
+                    color: root.statusColor
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/open-in-code.svg"
+                        height: 15
+                        width: 15
+                    }
+                    hoverEnabled: true
+                    onClicked: root.openInEditor(editData.edit_id)
+
+                    QoAToolTip {
+                        visible: parent.hovered
+                        delay: 500
+                        text: qsTr("Open file in editor and navigate to changes")
+                    }
+                }
+
+                Text {
+                    id: headerText
+                    text: {
+                        var modeText = root.oldContent.length > 0 ? qsTr("Replace") : qsTr("Append")
+                        if (root.oldContent.length > 0) {
+                            return qsTr("%1: %2 (+%3 -%4)")
+                                .arg(modeText)
+                                .arg(root.fileName)
+                                .arg(root.addedLines)
+                                .arg(root.removedLines)
+                        } else {
+                            return qsTr("%1: %2 (+%3)")
+                                .arg(modeText)
+                                .arg(root.fileName)
+                                .arg(root.addedLines)
+                        }
+                    }
+                    font.pixelSize: 12
+                    font.bold: true
+                    color: palette.text
+                    elide: Text.ElideMiddle
+                }
+
+                Text {
+                    text: fileEditView.expanded ? "▼" : "▶"
+                    font.pixelSize: 10
+                    color: palette.mid
+                }
+
+                Item { Layout.fillWidth: true }
+            }
+
+            RowLayout {
+                id: actionButtons
+
+                anchors {
+                    right: parent.right
+                    rightMargin: 5
+                    verticalCenter: parent.verticalCenter
+                }
+                spacing: 6
+
+                Rectangle {
+                    visible: !root.isPending
+                    Layout.preferredWidth: badgeText.width + 12
+                    Layout.preferredHeight: badgeText.height + 4
+                    color: root.statusBgColor
+                    radius: 3
+
+                    Text {
+                        id: badgeText
+                        anchors.centerIn: parent
+                        text: root.statusText
+                        font.pixelSize: 9
+                        font.bold: true
+                        color: root.isArchived ? Qt.rgba(0.6, 0.6, 0.6, 1.0) : palette.text
+                    }
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/apply-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }                    enabled: (root.isPending || root.isRejected) && !root.isArchived
+                    visible: !root.isApplied && !root.isArchived
+                    onClicked: root.applyEdit(editData.edit_id)
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/undo-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }
+                    enabled: root.isApplied && !root.isArchived
+                    visible: root.isApplied && !root.isArchived
+                    onClicked: root.undoEdit(editData.edit_id)
+                }
+
+                QoAButton {
+                    icon {
+                        source: "qrc:/qt/qml/ChatView/icons/reject-changes-button.svg"
+                        height: 15
+                        width: 15
+                    }
+                    enabled: root.isPending && !root.isArchived
+                    visible: root.isPending && !root.isArchived
+                    onClicked: root.rejectEdit(editData.edit_id)
+                }
+            }
+        }
+
+        ColumnLayout {
+            id: contentColumn
+
+            anchors {
+                left: parent.left
+                right: parent.right
+                top: headerArea.bottom
+                margins: root.contentMargin
+            }
+            spacing: 8
+            visible: opacity > 0
+
+            Text {
+                Layout.fillWidth: true
+                text: root.filePath
+                font.pixelSize: 10
+                color: palette.mid
+                elide: Text.ElideMiddle
+            }
+
+            Rectangle {
+                Layout.fillWidth: true
+                Layout.preferredHeight: oldContentColumn.implicitHeight + 12
+                color: Qt.rgba(1, 0.2, 0.2, 0.1)
+                radius: 4
+                border.width: 1
+                border.color: Qt.rgba(1, 0.2, 0.2, 0.3)
+                visible: root.oldContent.length > 0
+
+                Column {
+                    id: oldContentColumn
+                    width: parent.width
+                    x: 6
+                    y: 6
+                    spacing: 4
+
+                    TextEdit {
+                        id: oldContentText
+
+                        width: parent.width - 12
+                        height: contentHeight
+                        text: root.oldContent
+                        font.family: root.codeFontFamily
+                        font.pixelSize: root.codeFontSize
+                        color: palette.text
+                        wrapMode: TextEdit.Wrap
+                        readOnly: true
+                        selectByMouse: true
+                        selectByKeyboard: true
+                        textFormat: TextEdit.PlainText
+
+                        MouseArea {
+                            anchors.fill: parent
+                            acceptedButtons: Qt.RightButton
+                            onClicked: oldConentContextMenu.open()
+                        }
+                    }
+
+                    Platform.Menu {
+                        id: oldConentContextMenu
+
+                        Platform.MenuItem {
+                            text: qsTr("Copy")
+                            onTriggered: {
+                                const textToCopy = oldContentText.selectedText || root.oldContent
+                                utils.copyToClipboard(textToCopy)
+                            }
+                        }
+
+                        Platform.MenuSeparator {}
+
+                        Platform.MenuItem {
+                            text: fileEditView.expanded ? qsTr("Collapse") : qsTr("Expand")
+                            onTriggered: fileEditView.expanded = !fileEditView.expanded
+                        }
+                    }
+                }
+            }
+
+            Rectangle {
+                Layout.fillWidth: true
+                Layout.preferredHeight: newContentColumn.implicitHeight + 12
+                color: Qt.rgba(0.2, 0.8, 0.2, 0.1)
+                radius: 4
+                border.width: 1
+                border.color: Qt.rgba(0.2, 0.8, 0.2, 0.3)
+
+                Column {
+                    id: newContentColumn
+
+                    width: parent.width
+                    x: 6
+                    y: 6
+                    spacing: 4
+
+                    TextEdit {
+                        id: newContentText
+
+                        width: parent.width - 12
+                        height: contentHeight
+                        text: root.newContent
+                        font.family: root.codeFontFamily
+                        font.pixelSize: root.codeFontSize
+                        color: palette.text
+                        wrapMode: TextEdit.Wrap
+                        readOnly: true
+                        selectByMouse: true
+                        selectByKeyboard: true
+                        textFormat: TextEdit.PlainText
+
+                        MouseArea {
+                            anchors.fill: parent
+                            acceptedButtons: Qt.RightButton
+                            onClicked: newContentContextMenu.open()
+                        }
+                    }
+
+                    Platform.Menu {
+                        id: newContentContextMenu
+
+                        Platform.MenuItem {
+                            text: qsTr("Copy")
+                            onTriggered: {
+                                const textToCopy = newContentText.selectedText || root.newContent
+                                utils.copyToClipboard(textToCopy)
+                            }
+                        }
+
+                        Platform.MenuSeparator {}
+
+                        Platform.MenuItem {
+                            text: fileEditView.expanded ? qsTr("Collapse") : qsTr("Expand")
+                            onTriggered: fileEditView.expanded = !fileEditView.expanded
+                        }
+                    }
+                }
+            }
+
+            Text {
+                Layout.fillWidth: true
+                visible: root.statusMessage.length > 0
+                text: root.statusMessage
+                font.pixelSize: 10
+                font.italic: true
+                color: root.isApplied
+                    ? Qt.rgba(0.2, 0.6, 0.2, 1)
+                    : Qt.rgba(0.8, 0.2, 0.2, 1)
+                wrapMode: Text.WordWrap
+            }
+        }
+    }
+}

sources/ChatView/qml/chatparts/TextBlock.qml

@@ -0,0 +1,39 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+TextEdit {
+    id: root
+
+    readOnly: true
+    selectByMouse: true
+    wrapMode: Text.WordWrap
+    selectionColor: palette.highlight
+    color: palette.text
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        cursorShape: root.hoveredLink ? Qt.PointingHandCursor : Qt.IBeamCursor
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            enabled: root.selectedText.length > 0
+            onTriggered: root.copy()
+        }
+
+        Platform.MenuItem {
+            text: qsTr("Select All")
+            enabled: root.text.length > 0
+            onTriggered: root.selectAll()
+        }
+    }
+}

sources/ChatView/qml/chatparts/ThinkingBlock.qml

@@ -0,0 +1,168 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string thinkingContent: ""
+    // property string signature: ""
+    property bool isRedacted: false
+    property bool expanded: false
+    
+    property alias headerOpacity: headerRow.opacity
+
+    radius: 6
+    color: palette.base
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: headerRow.height + 10
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            width: parent.width
+            spacing: 8
+
+            Text {
+                text: root.isRedacted ? qsTr("Thinking (Redacted)")
+                                      : qsTr("Thinking")
+                font.pixelSize: 13
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    Column {
+        id: contentColumn
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        spacing: 8
+
+        Text {
+            visible: root.isRedacted
+            width: parent.width
+            text: qsTr("Thinking content was redacted by safety systems")
+            font.pixelSize: 11
+            font.italic: true
+            color: Qt.rgba(0.8, 0.4, 0.4, 1.0)
+            wrapMode: Text.WordWrap
+        }
+
+        TextEdit {
+            id: thinkingText
+
+            visible: !root.isRedacted
+            width: parent.width
+            text: root.thinkingContent
+            readOnly: true
+            selectByMouse: true
+            color: palette.text
+            wrapMode: Text.WordWrap
+            font.family: "monospace"
+            font.pixelSize: 11
+            selectionColor: palette.highlight
+        }
+
+        // Rectangle {
+        //     visible: root.signature.length > 0 && root.expanded
+        //     width: parent.width
+        //     height: signatureText.height + 10
+        //     color: palette.alternateBase
+        //     radius: 4
+
+        //     Text {
+        //         id: signatureText
+
+        //         anchors {
+        //             left: parent.left
+        //             right: parent.right
+        //             verticalCenter: parent.verticalCenter
+        //             margins: 5
+        //         }
+        //         text: qsTr("Signature: %1").arg(root.signature.substring(0, Math.min(40, root.signature.length)) + "...")
+        //         font.pixelSize: 9
+        //         font.family: "monospace"
+        //         color: palette.mid
+        //         elide: Text.ElideRight
+        //     }
+        // }
+    }
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        propagateComposedEvents: true
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    Rectangle {
+        id: thinkingMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: root.isRedacted ? Qt.rgba(0.8, 0.3, 0.3, 0.9)
+                               : (root.color.hslLightness > 0.5 ? Qt.darker(palette.alternateBase, 1.3)
+                                                                : Qt.lighter(palette.alternateBase, 1.3))
+        radius: root.radius
+    }
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + contentColumn.height + 20
+            }
+        }
+    ]
+}
+

sources/ChatView/qml/chatparts/ToolBlock.qml

@@ -0,0 +1,147 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import Qt.labs.platform as Platform
+
+Rectangle {
+    id: root
+
+    property string toolContent: ""
+    property bool expanded: false
+
+    property alias headerOpacity: headerRow.opacity
+
+    readonly property int firstNewline: toolContent.indexOf('\n')
+    readonly property string toolName: firstNewline > 0 ? toolContent.substring(0, firstNewline) : toolContent
+    readonly property string toolResult: firstNewline > 0 ? toolContent.substring(firstNewline + 1) : ""
+
+    radius: 6
+    color: palette.base
+    clip: true
+
+    Behavior on implicitHeight {
+        NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+    }
+
+    MouseArea {
+        id: header
+
+        width: parent.width
+        height: headerRow.height + 10
+        cursorShape: Qt.PointingHandCursor
+        onClicked: root.expanded = !root.expanded
+
+        Row {
+            id: headerRow
+
+            anchors {
+                verticalCenter: parent.verticalCenter
+                left: parent.left
+                leftMargin: 10
+            }
+            width: parent.width
+            spacing: 8
+
+            Text {
+                text: qsTr("Tool: %1").arg(root.toolName)
+                font.pixelSize: 13
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                anchors.verticalCenter: parent.verticalCenter
+                text: root.expanded ? "▼" : "▶"
+                font.pixelSize: 10
+                color: palette.mid
+            }
+        }
+    }
+
+    Column {
+        id: contentColumn
+
+        anchors {
+            left: parent.left
+            right: parent.right
+            top: header.bottom
+            margins: 10
+        }
+        spacing: 8
+
+        TextEdit {
+            id: resultText
+
+            width: parent.width
+            text: root.toolResult
+            readOnly: true
+            selectByMouse: true
+            color: palette.text
+            wrapMode: Text.WordWrap
+            font.family: "monospace"
+            font.pixelSize: 11
+            selectionColor: palette.highlight
+        }
+    }
+
+    MouseArea {
+        anchors.fill: parent
+        acceptedButtons: Qt.RightButton
+        onClicked: contextMenu.open()
+        propagateComposedEvents: true
+    }
+
+    Platform.Menu {
+        id: contextMenu
+
+        Platform.MenuItem {
+            text: qsTr("Copy")
+            enabled: resultText.selectedText.length > 0
+            onTriggered: resultText.copy()
+        }
+
+        Platform.MenuItem {
+            text: qsTr("Select All")
+            enabled: resultText.text.length > 0
+            onTriggered: resultText.selectAll()
+        }
+
+        Platform.MenuSeparator {}
+
+        Platform.MenuItem {
+            text: root.expanded ? qsTr("Collapse") : qsTr("Expand")
+            onTriggered: root.expanded = !root.expanded
+        }
+    }
+
+    Rectangle {
+        id: messageMarker
+
+        anchors.verticalCenter: parent.verticalCenter
+        width: 3
+        height: root.height - root.radius
+        color: root.color.hslLightness > 0.5 ? Qt.darker(palette.alternateBase, 1.3)
+                                             : Qt.lighter(palette.alternateBase, 1.3)
+        radius: root.radius
+    }
+
+
+    states: [
+        State {
+            when: !root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height
+            }
+        },
+        State {
+            when: root.expanded
+            PropertyChanges {
+                target: root
+                implicitHeight: header.height + contentColumn.height + 20
+            }
+        }
+    ]
+}

sources/ChatView/qml/controls/AttachedFilesPlace.qml

@@ -0,0 +1,147 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import Qt.labs.platform as Platform
+import ChatView
+import UIControls
+
+Flow {
+    id: root
+
+    property alias attachedFilesModel: attachRepeater.model
+    property color accentColor: palette.mid
+    property string iconPath
+
+    signal removeFileFromListByIndex(index: int)
+
+    spacing: 5
+    leftPadding: 5
+    rightPadding: 5
+    topPadding: attachRepeater.model.length > 0 ? 2 : 0
+    bottomPadding: attachRepeater.model.length > 0 ? 2 : 0
+
+    Repeater {
+        id: attachRepeater
+
+        delegate: FileItem {
+            id: fileItem
+
+            required property int index
+            required property string modelData
+
+            filePath: modelData
+
+            height: 30
+            width: contentRow.width + 10
+
+            Rectangle {
+                anchors.fill: parent
+                radius: 4
+                color: palette.button
+                border.width: 1
+                border.color: mouse.containsMouse ? palette.highlight : root.accentColor
+            }
+
+            MouseArea {
+                id: mouse
+
+                anchors.fill: parent
+                hoverEnabled: true
+                acceptedButtons: Qt.LeftButton | Qt.MiddleButton | Qt.RightButton
+                onClicked: (mouse) => {
+                    if (mouse.button === Qt.RightButton) {
+                        contextMenu.open()
+                    } else if (mouse.button === Qt.MiddleButton ||
+                        (mouse.button === Qt.LeftButton && (mouse.modifiers & Qt.ControlModifier))) {
+                        root.removeFileFromListByIndex(fileItem.index)
+                    } else if (mouse.modifiers & Qt.ShiftModifier) {
+                        fileItem.openFileInExternalEditor()
+                    } else {
+                        fileItem.openFileInEditor()
+                    }
+                }
+
+                QoAToolTip {
+                    visible: mouse.containsMouse
+                    delay: 500
+                    text: "Click: Open in Qt Creator\nShift+Click: Open in external editor\nCtrl+Click / Middle Click: Remove"
+                }
+            }
+
+            Platform.Menu {
+                id: contextMenu
+
+                Platform.MenuItem {
+                    text: qsTr("Open in Qt Creator")
+                    onTriggered: fileItem.openFileInEditor()
+                }
+
+                Platform.MenuItem {
+                    text: qsTr("Open in External Editor")
+                    onTriggered: fileItem.openFileInExternalEditor()
+                }
+
+                Platform.MenuSeparator {}
+
+                Platform.MenuItem {
+                    text: qsTr("Remove")
+                    onTriggered: root.removeFileFromListByIndex(fileItem.index)
+                }
+            }
+
+            Row {
+                id: contentRow
+
+                spacing: 5
+                anchors.verticalCenter: parent.verticalCenter
+                anchors.left: parent.left
+                anchors.leftMargin: 5
+
+                Image {
+                    id: icon
+
+                    anchors.verticalCenter: parent.verticalCenter
+                    source: root.iconPath
+                    sourceSize.width: 8
+                    sourceSize.height: 15
+                }
+
+                Text {
+                    id: fileNameText
+
+                    anchors.verticalCenter: parent.verticalCenter
+                    color: palette.buttonText
+
+                    text: {
+                        const parts = modelData.split('/');
+                        return parts[parts.length - 1];
+                    }
+                }
+
+                MouseArea {
+                    id: closeButton
+
+                    anchors.verticalCenter: parent.verticalCenter
+                    width: closeIcon.width + 5
+                    height: closeButton.width + 5
+
+                    onClicked: root.removeFileFromListByIndex(index)
+
+                    Image {
+                        id: closeIcon
+
+                        anchors.centerIn: parent
+                        source: palette.window.hslLightness > 0.5 ? "qrc:/qt/qml/ChatView/icons/close-dark.svg"
+                                                                  : "qrc:/qt/qml/ChatView/icons/close-light.svg"
+                        width: 6
+                        height: 6
+                    }
+                }
+            }
+        }
+    }
+}

sources/ChatView/qml/controls/BottomBar.qml

@@ -0,0 +1,190 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import ChatView
+import UIControls
+
+Rectangle {
+    id: root
+
+    property alias sendButton: sendButtonId
+    property alias syncOpenFiles: syncOpenFilesId
+    property alias attachFiles: attachFilesId
+    property alias attachImages: attachImagesId
+    property alias linkFiles: linkFilesId
+    property alias compressButton: compressButtonId
+    property alias cancelCompressButton: cancelCompressButtonId
+
+    property bool isCompressing: false
+    property bool isProcessing: false
+    property alias sendButtonTooltip: sendButtonTooltipId
+
+    color: palette.window.hslLightness > 0.5 ?
+               Qt.darker(palette.window, 1.1) :
+               Qt.lighter(palette.window, 1.1)
+
+    RowLayout {
+        id: bottomBar
+
+        anchors {
+            left: parent.left
+            leftMargin: 5
+            right: parent.right
+            rightMargin: 5
+            verticalCenter: parent.verticalCenter
+        }
+
+        spacing: 10
+
+        QoAButton {
+            id: attachFilesId
+
+            icon {
+                source: "qrc:/qt/qml/ChatView/icons/attach-file-dark.svg"
+                height: 15
+                width: 8
+            }
+
+            QoAToolTip {
+                visible: attachFilesId.hovered
+                delay: 250
+                text: qsTr("Attach file to message")
+            }
+        }
+
+        QoAButton {
+            id: attachImagesId
+
+            icon {
+                source: "qrc:/qt/qml/ChatView/icons/image-dark.svg"
+                height: 15
+                width: 15
+            }
+
+            QoAToolTip {
+                visible: attachImagesId.hovered
+                delay: 250
+                text: qsTr("Attach image to message")
+            }
+        }
+
+        QoAButton {
+            id: linkFilesId
+
+            icon {
+                source: "qrc:/qt/qml/ChatView/icons/link-file-dark.svg"
+                height: 15
+                width: 8
+            }
+
+            QoAToolTip {
+                visible: linkFilesId.hovered
+                delay: 250
+                text: qsTr("Link file to context")
+            }
+        }
+
+        CheckBox {
+            id: syncOpenFilesId
+
+            text: qsTr("Sync open files")
+
+            QoAToolTip {
+                visible: syncOpenFilesId.hovered
+                text: qsTr("Automatically synchronize currently opened files with the model context")
+            }
+        }
+
+        Item {
+            Layout.fillWidth: true
+        }
+
+        Row {
+            id: compressingRow
+
+            visible: root.isCompressing
+            spacing: 6
+
+            QoABusyIndicator {
+                id: compressBusyIndicator
+
+                anchors.verticalCenter: parent.verticalCenter
+                running: root.isCompressing
+                width: 16
+                height: 16
+            }
+
+            Text {
+                text: qsTr("Compressing...")
+                anchors.verticalCenter: parent.verticalCenter
+                color: palette.text
+                font.pixelSize: 12
+            }
+
+            QoAButton {
+                id: cancelCompressButtonId
+
+                anchors.verticalCenter: parent.verticalCenter
+                text: qsTr("Cancel")
+
+                QoAToolTip {
+                    visible: cancelCompressButtonId.hovered
+                    delay: 250
+                    text: qsTr("Cancel compression")
+                }
+            }
+        }
+
+        QoAButton {
+            id: compressButtonId
+
+            visible: !root.isCompressing
+            text: qsTr("Compress")
+
+            icon {
+                source: "qrc:/qt/qml/ChatView/icons/compress-icon.svg"
+                height: 15
+                width: 15
+            }
+
+            QoAToolTip {
+                visible: compressButtonId.hovered
+                delay: 250
+                text: qsTr("Compress chat (create summarized copy using LLM)")
+            }
+        }
+
+        QoAButton {
+            id: sendButtonId
+
+            leftPadding: root.isProcessing ? 22 : 4
+
+            icon {
+                height: 15
+                width: 15
+            }
+
+            QoABusyIndicator {
+                id: sendBusyIndicator
+
+                anchors.left: parent.left
+                anchors.leftMargin: 5
+                anchors.verticalCenter: parent.verticalCenter
+                width: 14
+                height: 14
+                running: root.isProcessing
+            }
+
+            QoAToolTip {
+                id: sendButtonTooltipId
+
+                visible: sendButtonId.hovered
+                delay: 250
+            }
+        }
+    }
+}

sources/ChatView/qml/controls/ContextViewer.qml

@@ -0,0 +1,543 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import QtQuick.Controls.Basic as QQC
+
+import UIControls
+import ChatView
+
+Popup {
+    id: root
+
+    property string baseSystemPrompt
+    property string currentAgentRole
+    property string currentAgentRoleDescription
+    property string currentAgentRoleSystemPrompt
+    property var activeRules
+    property int activeRulesCount
+    property string selectedRuleContent
+
+    signal openSettings()
+    signal openAgentRolesSettings()
+    signal openRulesFolder()
+    signal refreshRules()
+    signal ruleSelected(int index)
+
+    modal: true
+    focus: true
+    closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutside
+
+    background: Rectangle {
+        color: palette.window
+        border.color: palette.mid
+        border.width: 1
+        radius: 4
+    }
+
+    ChatUtils {
+        id: utils
+    }
+
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.margins: 10
+        spacing: 8
+
+        RowLayout {
+            Layout.fillWidth: true
+            spacing: 10
+
+            Text {
+                text: qsTr("Chat Context")
+                font.pixelSize: 16
+                font.bold: true
+                color: palette.text
+                Layout.fillWidth: true
+            }
+
+            QoAButton {
+                text: qsTr("Refresh")
+                onClicked: root.refreshRules()
+            }
+
+            QoAButton {
+                text: qsTr("Close")
+                onClicked: root.close()
+            }
+        }
+
+        Rectangle {
+            Layout.fillWidth: true
+            height: 1
+            color: palette.mid
+        }
+
+        Flickable {
+            id: mainFlickable
+
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            contentHeight: sectionsColumn.implicitHeight
+            clip: true
+            boundsBehavior: Flickable.StopAtBounds
+
+            ColumnLayout {
+                id: sectionsColumn
+
+                width: mainFlickable.width
+                spacing: 8
+
+                CollapsibleSection {
+                    id: systemPromptSection
+
+                    Layout.fillWidth: true
+                    title: qsTr("Base System Prompt")
+                    badge: root.baseSystemPrompt.length > 0 ? qsTr("Active") : qsTr("Empty")
+                    badgeColor: root.baseSystemPrompt.length > 0 ? Qt.rgba(0.2, 0.6, 0.3, 1.0) : palette.mid
+
+                    sectionContent: ColumnLayout {
+                        spacing: 5
+
+                        Rectangle {
+                            Layout.fillWidth: true
+                            Layout.preferredHeight: Math.min(Math.max(systemPromptText.implicitHeight + 16, 50), 200)
+                            color: palette.base
+                            border.color: palette.mid
+                            border.width: 1
+                            radius: 2
+
+                            Flickable {
+                                id: systemPromptFlickable
+
+                                anchors.fill: parent
+                                anchors.margins: 8
+                                contentHeight: systemPromptText.implicitHeight
+                                clip: true
+                                boundsBehavior: Flickable.StopAtBounds
+
+                                TextEdit {
+                                    id: systemPromptText
+
+                                    width: systemPromptFlickable.width
+                                    text: root.baseSystemPrompt.length > 0 ? root.baseSystemPrompt : qsTr("No system prompt configured")
+                                    readOnly: true
+                                    selectByMouse: true
+                                    wrapMode: Text.WordWrap
+                                    color: root.baseSystemPrompt.length > 0 ? palette.text : palette.mid
+                                    font.family: "monospace"
+                                    font.pixelSize: 11
+                                }
+
+                                QQC.ScrollBar.vertical: QQC.ScrollBar {
+                                    policy: systemPromptFlickable.contentHeight > systemPromptFlickable.height ? QQC.ScrollBar.AsNeeded : QQC.ScrollBar.AlwaysOff
+                                }
+                            }
+                        }
+
+                        RowLayout {
+                            Layout.fillWidth: true
+
+                            Item { Layout.fillWidth: true }
+
+                            QoAButton {
+                                text: qsTr("Copy")
+                                enabled: root.baseSystemPrompt.length > 0
+                                onClicked: utils.copyToClipboard(root.baseSystemPrompt)
+                            }
+
+                            QoAButton {
+                                text: qsTr("Edit in Settings")
+                                onClicked: {
+                                    root.openSettings()
+                                    root.close()
+                                }
+                            }
+                        }
+                    }
+                }
+
+                CollapsibleSection {
+                    id: agentRoleSection
+
+                    Layout.fillWidth: true
+                    title: qsTr("Agent Role")
+                    badge: root.currentAgentRole
+                    badgeColor: root.currentAgentRoleSystemPrompt.length > 0 ? Qt.rgba(0.3, 0.4, 0.7, 1.0) : palette.mid
+
+                    sectionContent: ColumnLayout {
+                        spacing: 8
+
+                        Text {
+                            text: root.currentAgentRoleDescription
+                            font.pixelSize: 11
+                            font.italic: true
+                            color: palette.mid
+                            wrapMode: Text.WordWrap
+                            Layout.fillWidth: true
+                            visible: root.currentAgentRoleDescription.length > 0
+                        }
+
+                        Rectangle {
+                            Layout.fillWidth: true
+                            Layout.preferredHeight: Math.min(Math.max(agentPromptText.implicitHeight + 16, 50), 200)
+                            color: palette.base
+                            border.color: palette.mid
+                            border.width: 1
+                            radius: 2
+                            visible: root.currentAgentRoleSystemPrompt.length > 0
+
+                            Flickable {
+                                id: agentPromptFlickable
+
+                                anchors.fill: parent
+                                anchors.margins: 8
+                                contentHeight: agentPromptText.implicitHeight
+                                clip: true
+                                boundsBehavior: Flickable.StopAtBounds
+
+                                TextEdit {
+                                    id: agentPromptText
+
+                                    width: agentPromptFlickable.width
+                                    text: root.currentAgentRoleSystemPrompt
+                                    readOnly: true
+                                    selectByMouse: true
+                                    wrapMode: Text.WordWrap
+                                    color: palette.text
+                                    font.family: "monospace"
+                                    font.pixelSize: 11
+                                }
+
+                                QQC.ScrollBar.vertical: QQC.ScrollBar {
+                                    policy: agentPromptFlickable.contentHeight > agentPromptFlickable.height ? QQC.ScrollBar.AsNeeded : QQC.ScrollBar.AlwaysOff
+                                }
+                            }
+                        }
+
+                        Text {
+                            text: qsTr("No role selected. Using base system prompt only.")
+                            font.pixelSize: 11
+                            color: palette.mid
+                            wrapMode: Text.WordWrap
+                            Layout.fillWidth: true
+                            visible: root.currentAgentRoleSystemPrompt.length === 0
+                        }
+
+                        RowLayout {
+                            Layout.fillWidth: true
+
+                            Item { Layout.fillWidth: true }
+
+                            QoAButton {
+                                text: qsTr("Copy")
+                                enabled: root.currentAgentRoleSystemPrompt.length > 0
+                                onClicked: utils.copyToClipboard(root.currentAgentRoleSystemPrompt)
+                            }
+
+                            QoAButton {
+                                text: qsTr("Manage Roles")
+                                onClicked: {
+                                    root.openAgentRolesSettings()
+                                    root.close()
+                                }
+                            }
+                        }
+                    }
+                }
+
+                CollapsibleSection {
+                    id: projectRulesSection
+
+                    Layout.fillWidth: true
+                    title: qsTr("Project Rules")
+                    badge: root.activeRulesCount > 0 ? qsTr("%1 active").arg(root.activeRulesCount) : qsTr("None")
+                    badgeColor: root.activeRulesCount > 0 ? Qt.rgba(0.6, 0.5, 0.2, 1.0) : palette.mid
+
+                    sectionContent: ColumnLayout {
+                        spacing: 8
+
+                        SplitView {
+                            Layout.fillWidth: true
+                            Layout.preferredHeight: 220
+                            orientation: Qt.Horizontal
+                            visible: root.activeRulesCount > 0
+
+                            Rectangle {
+                                SplitView.minimumWidth: 120
+                                SplitView.preferredWidth: 180
+                                color: palette.base
+                                border.color: palette.mid
+                                border.width: 1
+                                radius: 2
+
+                                ColumnLayout {
+                                    anchors.fill: parent
+                                    anchors.margins: 5
+                                    spacing: 5
+
+                                    Text {
+                                        text: qsTr("Rules (%1)").arg(rulesList.count)
+                                        font.pixelSize: 11
+                                        font.bold: true
+                                        color: palette.text
+                                        Layout.fillWidth: true
+                                    }
+
+                                    ListView {
+                                        id: rulesList
+
+                                        Layout.fillWidth: true
+                                        Layout.fillHeight: true
+                                        clip: true
+                                        model: root.activeRules
+                                        currentIndex: 0
+                                        boundsBehavior: Flickable.StopAtBounds
+
+                                        delegate: ItemDelegate {
+                                            required property var modelData
+                                            required property int index
+
+                                            width: ListView.view.width
+                                            height: ruleItemContent.implicitHeight + 8
+                                            highlighted: ListView.isCurrentItem
+
+                                            background: Rectangle {
+                                                color: {
+                                                    if (parent.highlighted)
+                                                        return palette.highlight
+                                                    if (parent.hovered)
+                                                        return Qt.tint(palette.base, Qt.rgba(0, 0, 0, 0.05))
+                                                    return "transparent"
+                                                }
+                                                radius: 2
+                                            }
+
+                                            contentItem: ColumnLayout {
+                                                id: ruleItemContent
+                                                spacing: 2
+
+                                                Text {
+                                                    text: modelData.fileName
+                                                    font.pixelSize: 10
+                                                    color: parent.parent.highlighted ? palette.highlightedText : palette.text
+                                                    elide: Text.ElideMiddle
+                                                    Layout.fillWidth: true
+                                                }
+
+                                                Text {
+                                                    text: modelData.category
+                                                    font.pixelSize: 9
+                                                    color: parent.parent.highlighted ? palette.highlightedText : palette.mid
+                                                    Layout.fillWidth: true
+                                                }
+                                            }
+
+                                            onClicked: {
+                                                rulesList.currentIndex = index
+                                                root.ruleSelected(index)
+                                            }
+                                        }
+
+                                        QQC.ScrollBar.vertical: QQC.ScrollBar {
+                                            policy: rulesList.contentHeight > rulesList.height ? QQC.ScrollBar.AsNeeded : QQC.ScrollBar.AlwaysOff
+                                        }
+                                    }
+                                }
+                            }
+
+                            Rectangle {
+                                SplitView.fillWidth: true
+                                SplitView.minimumWidth: 200
+                                color: palette.base
+                                border.color: palette.mid
+                                border.width: 1
+                                radius: 2
+
+                                ColumnLayout {
+                                    anchors.fill: parent
+                                    anchors.margins: 5
+                                    spacing: 5
+
+                                    RowLayout {
+                                        Layout.fillWidth: true
+                                        spacing: 5
+
+                                        Text {
+                                            text: qsTr("Content")
+                                            font.pixelSize: 11
+                                            font.bold: true
+                                            color: palette.text
+                                            Layout.fillWidth: true
+                                        }
+
+                                        QoAButton {
+                                            text: qsTr("Copy")
+                                            enabled: root.selectedRuleContent.length > 0
+                                            onClicked: utils.copyToClipboard(root.selectedRuleContent)
+                                        }
+                                    }
+
+                                    Flickable {
+                                        id: ruleContentFlickable
+
+                                        Layout.fillWidth: true
+                                        Layout.fillHeight: true
+                                        contentHeight: ruleContentArea.implicitHeight
+                                        clip: true
+                                        boundsBehavior: Flickable.StopAtBounds
+
+                                        TextEdit {
+                                            id: ruleContentArea
+
+                                            width: ruleContentFlickable.width
+                                            text: root.selectedRuleContent
+                                            readOnly: true
+                                            selectByMouse: true
+                                            wrapMode: Text.WordWrap
+                                            selectionColor: palette.highlight
+                                            color: palette.text
+                                            font.family: "monospace"
+                                            font.pixelSize: 11
+                                        }
+
+                                        QQC.ScrollBar.vertical: QQC.ScrollBar {
+                                            policy: ruleContentFlickable.contentHeight > ruleContentFlickable.height ? QQC.ScrollBar.AsNeeded : QQC.ScrollBar.AlwaysOff
+                                        }
+                                    }
+                                }
+                            }
+                        }
+
+                        Text {
+                            text: qsTr("No project rules found.\nCreate .md files in .qodeassist/rules/common/ or .qodeassist/rules/chat/")
+                            font.pixelSize: 11
+                            color: palette.mid
+                            wrapMode: Text.WordWrap
+                            horizontalAlignment: Text.AlignHCenter
+                            Layout.fillWidth: true
+                            visible: root.activeRulesCount === 0
+                        }
+
+                        RowLayout {
+                            Layout.fillWidth: true
+
+                            Item { Layout.fillWidth: true }
+
+                            QoAButton {
+                                text: qsTr("Open Rules Folder")
+                                onClicked: root.openRulesFolder()
+                            }
+                        }
+                    }
+                }
+            }
+
+            QQC.ScrollBar.vertical: QQC.ScrollBar {
+                policy: mainFlickable.contentHeight > mainFlickable.height ? QQC.ScrollBar.AsNeeded : QQC.ScrollBar.AlwaysOff
+            }
+        }
+
+        Rectangle {
+            Layout.fillWidth: true
+            height: 1
+            color: palette.mid
+        }
+
+        Text {
+            text: qsTr("Final prompt: Base System Prompt + Agent Role + Project Info + Project Rules + Linked Files")
+            font.pixelSize: 9
+            color: palette.mid
+            wrapMode: Text.WordWrap
+            Layout.fillWidth: true
+        }
+    }
+
+    component CollapsibleSection: ColumnLayout {
+        id: sectionRoot
+
+        property string title
+        property string badge
+        property color badgeColor: palette.mid
+        property Component sectionContent: null
+        property bool expanded: false
+
+        spacing: 0
+
+        Rectangle {
+            Layout.fillWidth: true
+            Layout.preferredHeight: 32
+            color: sectionMouseArea.containsMouse ? Qt.tint(palette.button, Qt.rgba(0, 0, 0, 0.05)) : palette.button
+            border.color: palette.mid
+            border.width: 1
+            radius: 2
+
+            MouseArea {
+                id: sectionMouseArea
+
+                anchors.fill: parent
+                hoverEnabled: true
+                cursorShape: Qt.PointingHandCursor
+                onClicked: sectionRoot.expanded = !sectionRoot.expanded
+            }
+
+            RowLayout {
+                anchors.fill: parent
+                anchors.leftMargin: 8
+                anchors.rightMargin: 8
+                spacing: 8
+
+                Text {
+                    text: sectionRoot.expanded ? "▼" : "▶"
+                    font.pixelSize: 10
+                    color: palette.text
+                }
+
+                Text {
+                    text: sectionRoot.title
+                    font.pixelSize: 12
+                    font.bold: true
+                    color: palette.text
+                    Layout.fillWidth: true
+                }
+
+                Rectangle {
+                    implicitWidth: badgeText.implicitWidth + 12
+                    implicitHeight: 18
+                    color: sectionRoot.badgeColor
+                    radius: 3
+
+                    Text {
+                        id: badgeText
+
+                        anchors.centerIn: parent
+                        text: sectionRoot.badge
+                        font.pixelSize: 10
+                        color: "#FFFFFF"
+                    }
+                }
+            }
+        }
+
+        Loader {
+            id: contentLoader
+
+            Layout.fillWidth: true
+            Layout.leftMargin: 12
+            Layout.topMargin: 8
+            Layout.bottomMargin: 4
+            sourceComponent: sectionRoot.sectionContent
+            visible: sectionRoot.expanded
+            active: sectionRoot.expanded
+        }
+    }
+
+    onOpened: {
+        if (root.activeRulesCount > 0) {
+            root.ruleSelected(0)
+        }
+    }
+}

sources/ChatView/qml/controls/FileEditsActionBar.qml

@@ -0,0 +1,150 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+import UIControls
+
+Rectangle {
+    id: root
+
+    property int totalEdits: 0
+    property int appliedEdits: 0
+    property int pendingEdits: 0
+    property int rejectedEdits: 0
+    property bool hasAppliedEdits: appliedEdits > 0
+    property bool hasRejectedEdits: rejectedEdits > 0
+    property bool hasPendingEdits: pendingEdits > 0
+
+    signal applyAllClicked()
+    signal undoAllClicked()
+
+    visible: totalEdits > 0
+    implicitHeight: visible ? 40 : 0
+
+    color: palette.window.hslLightness > 0.5 ?
+               Qt.darker(palette.window, 1.05) :
+               Qt.lighter(palette.window, 1.05)
+
+    border.width: 1
+    border.color: palette.mid
+
+    Behavior on implicitHeight {
+        NumberAnimation {
+            duration: 200
+            easing.type: Easing.InOutQuad
+        }
+    }
+
+    RowLayout {
+        anchors {
+            left: parent.left
+            leftMargin: 10
+            right: parent.right
+            rightMargin: 10
+            verticalCenter: parent.verticalCenter
+        }
+        spacing: 10
+
+        Rectangle {
+            Layout.preferredWidth: 24
+            Layout.preferredHeight: 24
+            radius: 12
+            color: {
+                if (root.hasPendingEdits) return Qt.rgba(0.2, 0.6, 1.0, 0.2)
+                if (root.hasAppliedEdits) return Qt.rgba(0.2, 0.8, 0.2, 0.2)
+                return Qt.rgba(0.8, 0.6, 0.2, 0.2)
+            }
+            border.width: 2
+            border.color: {
+                if (root.hasPendingEdits) return Qt.rgba(0.2, 0.6, 1.0, 0.8)
+                if (root.hasAppliedEdits) return Qt.rgba(0.2, 0.8, 0.2, 0.8)
+                return Qt.rgba(0.8, 0.6, 0.2, 0.8)
+            }
+
+            Text {
+                anchors.centerIn: parent
+                text: root.totalEdits
+                font.pixelSize: 10
+                font.bold: true
+                color: palette.text
+            }
+        }
+
+        // Status text
+        ColumnLayout {
+            spacing: 2
+
+            Text {
+                text: root.totalEdits === 1 
+                    ? qsTr("File Edit in Current Message")
+                    : qsTr("%1 File Edits in Current Message").arg(root.totalEdits)
+                font.pixelSize: 11
+                font.bold: true
+                color: palette.text
+            }
+
+            Text {
+                visible: root.totalEdits > 0
+                text: {
+                    let parts = [];
+                    if (root.appliedEdits > 0) {
+                        parts.push(qsTr("%1 applied").arg(root.appliedEdits));
+                    }
+                    if (root.pendingEdits > 0) {
+                        parts.push(qsTr("%1 pending").arg(root.pendingEdits));
+                    }
+                    if (root.rejectedEdits > 0) {
+                        parts.push(qsTr("%1 rejected").arg(root.rejectedEdits));
+                    }
+                    return parts.join(", ");
+                }
+                font.pixelSize: 9
+                color: palette.mid
+            }
+        }
+
+        Item {
+            Layout.fillWidth: true
+        }
+
+        QoAButton {
+            id: applyAllButton
+
+            visible: root.hasPendingEdits || root.hasRejectedEdits
+            enabled: root.hasPendingEdits || root.hasRejectedEdits
+            text: root.hasPendingEdits 
+                ? qsTr("Apply All (%1)").arg(root.pendingEdits + root.rejectedEdits)
+                : qsTr("Reapply All (%1)").arg(root.rejectedEdits)
+
+            QoAToolTip {
+                visible: applyAllButton.hovered
+                delay: 250
+                text: root.hasPendingEdits
+                    ? qsTr("Apply all pending and rejected edits in this message")
+                    : qsTr("Reapply all rejected edits in this message")
+            }
+
+            onClicked: root.applyAllClicked()
+        }
+
+        QoAButton {
+            id: undoAllButton
+
+            visible: root.hasAppliedEdits
+            enabled: root.hasAppliedEdits
+            text: qsTr("Undo All (%1)").arg(root.appliedEdits)
+
+            QoAToolTip {
+                visible: undoAllButton.hovered
+                delay: 250
+                text: qsTr("Undo all applied edits in this message")
+            }
+
+            onClicked: root.undoAllClicked()
+        }
+    }
+}
+

sources/ChatView/qml/controls/FileMentionPopup.qml

@@ -0,0 +1,152 @@
+// Copyright (C) 2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+
+FileMentionItem {
+    id: root
+
+    signal selectionRequested()
+
+    visible: searchResults.length > 0
+    height: Math.min(searchResults.length * 36, 36 * 6) + 2
+
+    onCurrentIndexChanged: {
+        listView.positionViewAtIndex(root.currentIndex, ListView.Contain)
+    }
+
+    Rectangle {
+        id: background
+
+        anchors.fill: parent
+        color: palette.window
+        border.color: palette.mid
+        border.width: 1
+        radius: 4
+    }
+
+    ListView {
+        id: listView
+
+        anchors.fill: parent
+        anchors.margins: 1
+        model: root.searchResults
+        currentIndex: root.currentIndex
+        clip: true
+
+        ScrollBar.vertical: ScrollBar {
+            policy: ScrollBar.AsNeeded
+        }
+
+        delegate: Rectangle {
+            id: delegateItem
+
+            required property int index
+            required property var modelData
+
+            readonly property bool isProject: modelData.isProject === true
+            readonly property bool isOpen: modelData.isOpen === true
+            readonly property string fileName: {
+                if (isProject)
+                    return modelData.projectName
+                const parts = modelData.relativePath.split('/')
+                return parts[parts.length - 1]
+            }
+
+            width: listView.width
+            height: 36
+            color: index === root.currentIndex
+                   ? palette.highlight
+                   : (hoverArea.containsMouse
+                      ? Qt.rgba(palette.highlight.r, palette.highlight.g, palette.highlight.b, 0.25)
+                      : "transparent")
+
+            RowLayout {
+                anchors.fill: parent
+                anchors.leftMargin: 10
+                anchors.rightMargin: 10
+                spacing: 8
+
+                Item {
+                    Layout.preferredWidth: 18
+                    Layout.preferredHeight: 18
+
+                    Rectangle {
+                        anchors.fill: parent
+                        radius: 3
+                        visible: delegateItem.isProject || delegateItem.isOpen
+
+                        color: {
+                            if (delegateItem.index === root.currentIndex)
+                                return Qt.rgba(palette.highlightedText.r,
+                                               palette.highlightedText.g,
+                                               palette.highlightedText.b, 0.2)
+                            if (delegateItem.isProject)
+                                return Qt.rgba(palette.highlight.r,
+                                               palette.highlight.g,
+                                               palette.highlight.b, 0.3)
+                            return Qt.rgba(0.2, 0.7, 0.4, 0.3)
+                        }
+
+                        Text {
+                            anchors.centerIn: parent
+                            text: delegateItem.isProject ? "P" : "O"
+                            font.bold: true
+                            font.pixelSize: 10
+                            color: {
+                                if (delegateItem.index === root.currentIndex)
+                                    return palette.highlightedText
+                                if (delegateItem.isProject)
+                                    return palette.highlight
+                                return Qt.rgba(0.1, 0.6, 0.3, 1.0)
+                            }
+                        }
+                    }
+                }
+
+                Text {
+                    Layout.preferredWidth: 160
+                    text: delegateItem.fileName
+                    color: delegateItem.index === root.currentIndex
+                           ? palette.highlightedText
+                           : (delegateItem.isProject ? palette.highlight : palette.text)
+                    font.bold: true
+                    font.italic: delegateItem.isProject
+                    elide: Text.ElideRight
+                }
+
+                Text {
+                    Layout.fillWidth: true
+                    text: delegateItem.isProject
+                          ? "→"
+                          : (delegateItem.modelData.projectName + " / " + delegateItem.modelData.relativePath)
+                    color: delegateItem.index === root.currentIndex
+                           ? (delegateItem.isProject
+                              ? palette.highlightedText
+                              : Qt.rgba(palette.highlightedText.r,
+                                        palette.highlightedText.g,
+                                        palette.highlightedText.b, 0.7))
+                           : palette.mid
+                    font.pixelSize: delegateItem.isProject ? 12 : 11
+                    elide: Text.ElideLeft
+                    horizontalAlignment: delegateItem.isProject ? Text.AlignLeft : Text.AlignRight
+                }
+            }
+
+            MouseArea {
+                id: hoverArea
+
+                anchors.fill: parent
+                hoverEnabled: true
+                onClicked: {
+                    root.currentIndex = delegateItem.index
+                    root.selectionRequested()
+                }
+                onEntered: root.currentIndex = delegateItem.index
+            }
+        }
+    }
+}

sources/ChatView/qml/controls/MessageNavigator.qml

@@ -0,0 +1,188 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import ChatView
+import UIControls
+
+Item {
+    id: nav
+
+    property var chatModel
+    property var entries: []
+    property color dotColor: "#92BD6C"
+    property int currentMessageIndex: -1
+
+    readonly property int dotCount: entries.length
+    readonly property int verticalPadding: 8
+    readonly property int minDotSpacing: 18
+    readonly property real availableHeight: Math.max(0, height - 2 * verticalPadding)
+    readonly property real naturalHeight: dotCount > 1 ? (dotCount - 1) * minDotSpacing : 0
+    readonly property bool needsScrolling: naturalHeight > availableHeight
+    readonly property real contentHeight: needsScrolling
+        ? naturalHeight + 2 * verticalPadding
+        : Math.max(height, 2 * verticalPadding)
+
+    signal messageClicked(int messageIndex)
+
+    implicitWidth: 16
+
+    function rebuild() {
+        entries = chatModel ? chatModel.userMessagePreviews(80) : []
+        Qt.callLater(scrollCurrentIntoView)
+    }
+
+    function updateCurrentFromModelIndex(modelIdx) {
+        if (modelIdx < 0) {
+            currentMessageIndex = -1
+            return
+        }
+        let best = -1
+        for (let i = 0; i < entries.length; ++i) {
+            const e = entries[i]
+            if (!e)
+                continue
+            const mi = e.messageIndex
+            if (mi <= modelIdx)
+                best = mi
+            else
+                break
+        }
+        currentMessageIndex = best
+    }
+
+    function uiIndexOf(messageIndex) {
+        for (let i = 0; i < entries.length; ++i) {
+            const e = entries[i]
+            if (e && e.messageIndex === messageIndex)
+                return i
+        }
+        return -1
+    }
+
+    function dotCenterY(uiIndex) {
+        const count = dotCount
+        if (count <= 1)
+            return contentHeight / 2
+        const spacing = needsScrolling
+            ? minDotSpacing
+            : availableHeight / (count - 1)
+        return verticalPadding + spacing * uiIndex
+    }
+
+    function scrollCurrentIntoView() {
+        if (!needsScrolling || currentMessageIndex < 0)
+            return
+        const ui = uiIndexOf(currentMessageIndex)
+        if (ui < 0)
+            return
+        const y = dotCenterY(ui)
+        const margin = 24
+        if (y < flick.contentY + margin)
+            flick.contentY = Math.max(0, y - margin)
+        else if (y > flick.contentY + flick.height - margin)
+            flick.contentY = Math.min(
+                Math.max(0, flick.contentHeight - flick.height),
+                y - flick.height + margin)
+    }
+
+    onChatModelChanged: rebuild()
+    onCurrentMessageIndexChanged: scrollCurrentIntoView()
+    Component.onCompleted: rebuild()
+
+    Connections {
+        target: nav.chatModel
+        ignoreUnknownSignals: true
+        function onRowsInserted() { nav.rebuild() }
+        function onRowsRemoved() { nav.rebuild() }
+        function onModelReset() { nav.rebuild() }
+        function onModelReseted() { nav.rebuild() }
+        function onDataChanged() { nav.rebuild() }
+    }
+
+    Flickable {
+        id: flick
+
+        anchors.fill: parent
+        contentWidth: width
+        contentHeight: nav.contentHeight
+        interactive: nav.needsScrolling
+        clip: true
+        boundsBehavior: Flickable.StopAtBounds
+
+        Rectangle {
+            id: spine
+
+            visible: nav.dotCount > 1
+            anchors.horizontalCenter: parent.horizontalCenter
+            y: nav.verticalPadding
+            width: 1
+            height: Math.max(0, flick.contentHeight - 2 * nav.verticalPadding)
+            color: palette.mid
+            opacity: 0.4
+        }
+
+        Repeater {
+            model: nav.entries
+
+            delegate: Item {
+                id: dotItem
+
+                required property var modelData
+                required property int index
+
+                readonly property int msgIndex: modelData && modelData.messageIndex !== undefined
+                                                ? modelData.messageIndex : -1
+                readonly property string preview: modelData && modelData.preview !== undefined
+                                                  ? modelData.preview : ""
+                readonly property bool isCurrent: nav.currentMessageIndex === msgIndex
+
+                width: 16
+                height: 14
+                anchors.horizontalCenter: parent.horizontalCenter
+                y: nav.dotCenterY(index) - height / 2
+
+                Rectangle {
+                    id: dot
+
+                    anchors.centerIn: parent
+                    width: dotItem.isCurrent ? 11 : (dotArea.containsMouse ? 10 : 7)
+                    height: width
+                    radius: width / 2
+                    color: dotArea.containsMouse
+                           ? Qt.lighter(nav.dotColor, 1.2)
+                           : nav.dotColor
+                    border.color: dotItem.isCurrent
+                                  ? Qt.darker(nav.dotColor, 1.7)
+                                  : Qt.darker(nav.dotColor, 1.4)
+                    border.width: dotItem.isCurrent ? 2 : 1
+                    opacity: dotItem.isCurrent || dotArea.containsMouse ? 1.0 : 0.55
+
+                    Behavior on width { NumberAnimation { duration: 120 } }
+                    Behavior on opacity { NumberAnimation { duration: 120 } }
+                    Behavior on color { ColorAnimation { duration: 120 } }
+                }
+
+                MouseArea {
+                    id: dotArea
+
+                    anchors.fill: parent
+                    hoverEnabled: true
+                    cursorShape: Qt.PointingHandCursor
+                    onClicked: nav.messageClicked(dotItem.msgIndex)
+
+                    QoAToolTip {
+                        visible: dotArea.containsMouse
+                        delay: 350
+                        text: dotItem.preview.length > 0
+                              ? qsTr("#%1  ·  %2").arg(dotItem.index + 1).arg(dotItem.preview)
+                              : qsTr("Jump to message #%1").arg(dotItem.index + 1)
+                    }
+                }
+            }
+        }
+    }
+
+}

sources/ChatView/qml/controls/SkillCommandPopup.qml

@@ -0,0 +1,126 @@
+// Copyright (C) 2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+import QtQuick.Layouts
+
+Rectangle {
+    id: root
+
+    // Object exposing Q_INVOKABLE QVariantList searchSkills(query).
+    property var skillProvider: null
+    property var searchResults: []
+    property int currentIndex: 0
+
+    signal selectionRequested()
+
+    visible: searchResults.length > 0
+    height: Math.min(searchResults.length * 40, 40 * 6) + 2
+
+    color: palette.window
+    border.color: palette.mid
+    border.width: 1
+    radius: 4
+
+    function updateSearch(query) {
+        searchResults = skillProvider ? skillProvider.searchSkills(query) : []
+        currentIndex = 0
+    }
+
+    function dismiss() {
+        searchResults = []
+        currentIndex = 0
+    }
+
+    function moveUp() {
+        if (currentIndex > 0)
+            currentIndex--
+    }
+
+    function moveDown() {
+        if (currentIndex < searchResults.length - 1)
+            currentIndex++
+    }
+
+    function currentName() {
+        if (currentIndex >= 0 && currentIndex < searchResults.length)
+            return searchResults[currentIndex].name
+        return ""
+    }
+
+    onCurrentIndexChanged: listView.positionViewAtIndex(currentIndex, ListView.Contain)
+
+    ListView {
+        id: listView
+
+        anchors.fill: parent
+        anchors.margins: 1
+        model: root.searchResults
+        currentIndex: root.currentIndex
+        clip: true
+
+        ScrollBar.vertical: ScrollBar {
+            policy: ScrollBar.AsNeeded
+        }
+
+        delegate: Rectangle {
+            id: delegateItem
+
+            required property int index
+            required property var modelData
+
+            width: listView.width
+            height: 40
+            color: index === root.currentIndex
+                   ? palette.highlight
+                   : (hoverArea.containsMouse
+                      ? Qt.rgba(palette.highlight.r, palette.highlight.g, palette.highlight.b, 0.25)
+                      : "transparent")
+
+            ColumnLayout {
+                anchors.fill: parent
+                anchors.leftMargin: 10
+                anchors.rightMargin: 10
+                anchors.topMargin: 4
+                anchors.bottomMargin: 4
+                spacing: 1
+
+                Text {
+                    Layout.fillWidth: true
+                    text: "/" + delegateItem.modelData.name
+                    color: delegateItem.index === root.currentIndex
+                           ? palette.highlightedText
+                           : palette.text
+                    font.bold: true
+                    elide: Text.ElideRight
+                }
+
+                Text {
+                    Layout.fillWidth: true
+                    text: delegateItem.modelData.description
+                    color: delegateItem.index === root.currentIndex
+                           ? Qt.rgba(palette.highlightedText.r,
+                                     palette.highlightedText.g,
+                                     palette.highlightedText.b, 0.7)
+                           : palette.mid
+                    font.pixelSize: 11
+                    elide: Text.ElideRight
+                }
+            }
+
+            MouseArea {
+                id: hoverArea
+
+                anchors.fill: parent
+                hoverEnabled: true
+                onClicked: {
+                    root.currentIndex = delegateItem.index
+                    root.selectionRequested()
+                }
+                onEntered: root.currentIndex = delegateItem.index
+            }
+        }
+    }
+}

sources/ChatView/qml/controls/SplitDropZone.qml

@@ -0,0 +1,276 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Controls
+
+Item {
+    id: root
+
+    signal filesDroppedToAttach(var urlStrings)
+    signal filesDroppedToLink(var urlStrings)
+
+    property string activeZone: ""
+    property int filesCount: 0
+    property bool isDragActive: false
+
+    Item {
+        id: splitDropOverlay
+
+        anchors.fill: parent
+        visible: false
+        z: 999
+        opacity: 0
+
+        Behavior on opacity {
+            NumberAnimation { duration: 200; easing.type: Easing.InOutQuad }
+        }
+
+        Rectangle {
+            anchors.fill: parent
+            color: Qt.rgba(palette.shadow.r, palette.shadow.g, palette.shadow.b, 0.6)
+        }
+
+        Rectangle {
+            anchors {
+                top: parent.top
+                horizontalCenter: parent.horizontalCenter
+                topMargin: 30
+            }
+            width: fileCountText.width + 40
+            height: 50
+            color: Qt.rgba(palette.highlight.r, palette.highlight.g, palette.highlight.b, 0.9)
+            radius: 25
+            visible: root.filesCount > 0
+            
+            Text {
+                id: fileCountText
+                anchors.centerIn: parent
+                text: qsTr("%n file(s) to drop", "", root.filesCount)
+                font.pixelSize: 16
+                font.bold: true
+                color: palette.highlightedText
+            }
+        }
+
+        Rectangle {
+            id: leftZone
+
+            anchors {
+                left: parent.left
+                top: parent.top
+                bottom: parent.bottom
+            }
+            width: parent.width / 2
+            color: root.activeZone === "left"
+                   ? Qt.rgba(palette.highlight.r, palette.highlight.g, palette.highlight.b, 0.3)
+                   : Qt.rgba(palette.mid.r, palette.mid.g, palette.mid.b, 0.15)
+            border.width: root.activeZone === "left" ? 3 : 2
+            border.color: root.activeZone === "left"
+                          ? palette.highlight
+                          : Qt.rgba(palette.mid.r, palette.mid.g, palette.mid.b, 0.5)
+
+            Column {
+                anchors.centerIn: parent
+                spacing: 15
+
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("Attach")
+                    font.pixelSize: 24
+                    font.bold: true
+                    color: root.activeZone === "left" ? palette.highlightedText : palette.text
+                }
+
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("Images & Text Files")
+                    font.pixelSize: 14
+                    color: root.activeZone === "left" ? palette.highlightedText : palette.text
+                    opacity: 0.8
+                }
+                
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("(for one-time use)")
+                    font.pixelSize: 12
+                    font.italic: true
+                    color: root.activeZone === "left" ? palette.highlightedText : palette.text
+                    opacity: 0.6
+                }
+            }
+
+            Behavior on color { ColorAnimation { duration: 150 } }
+            Behavior on border.width { NumberAnimation { duration: 150 } }
+            Behavior on border.color { ColorAnimation { duration: 150 } }
+        }
+
+        Rectangle {
+            id: rightZone
+
+            anchors {
+                right: parent.right
+                top: parent.top
+                bottom: parent.bottom
+            }
+            width: parent.width / 2
+            color: root.activeZone === "right"
+                   ? Qt.rgba(palette.highlight.r, palette.highlight.g, palette.highlight.b, 0.3)
+                   : Qt.rgba(palette.mid.r, palette.mid.g, palette.mid.b, 0.15)
+            border.width: root.activeZone === "right" ? 3 : 2
+            border.color: root.activeZone === "right"
+                          ? palette.highlight
+                          : Qt.rgba(palette.mid.r, palette.mid.g, palette.mid.b, 0.5)
+
+            Column {
+                anchors.centerIn: parent
+                spacing: 15
+
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("LINK")
+                    font.pixelSize: 24
+                    font.bold: true
+                    color: root.activeZone === "right" ? palette.highlightedText : palette.text
+                }
+
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("Text Files")
+                    font.pixelSize: 14
+                    color: root.activeZone === "right" ? palette.highlightedText : palette.text
+                    opacity: 0.8
+                }
+                
+                Text {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    text: qsTr("(added to context)")
+                    font.pixelSize: 12
+                    font.italic: true
+                    color: root.activeZone === "right" ? palette.highlightedText : palette.text
+                    opacity: 0.6
+                }
+            }
+
+            Behavior on color { ColorAnimation { duration: 150 } }
+            Behavior on border.width { NumberAnimation { duration: 150 } }
+            Behavior on border.color { ColorAnimation { duration: 150 } }
+        }
+
+        Rectangle {
+            anchors {
+                horizontalCenter: parent.horizontalCenter
+                top: parent.top
+                bottom: parent.bottom
+            }
+            width: 2
+            color: palette.mid
+            opacity: 0.4
+        }
+
+        MouseArea {
+            id: leftDropArea
+
+            anchors {
+                left: parent.left
+                top: parent.top
+                bottom: parent.bottom
+            }
+            width: parent.width / 2
+            hoverEnabled: true
+
+            onEntered: {
+                root.activeZone = "left"
+            }
+        }
+
+        MouseArea {
+            id: rightDropArea
+
+            anchors {
+                right: parent.right
+                top: parent.top
+                bottom: parent.bottom
+            }
+            width: parent.width / 2
+            hoverEnabled: true
+
+            onEntered: {
+                root.activeZone = "right"
+            }
+        }
+    }
+
+    DropArea {
+        id: globalDropArea
+
+        anchors.fill: parent
+        
+        onEntered: (drag) => {
+                       if (drag.hasUrls) {
+                           root.isDragActive = true
+                           root.filesCount = drag.urls.length
+                           splitDropOverlay.visible = true
+                           splitDropOverlay.opacity = 1
+                           root.activeZone = ""
+                       }
+                   }
+
+        onExited: {
+            root.isDragActive = false
+            root.filesCount = 0
+            splitDropOverlay.opacity = 0
+
+            Qt.callLater(function() {
+                if (!root.isDragActive) {
+                    splitDropOverlay.visible = false
+                    root.activeZone = ""
+                }
+            })
+        }
+
+        onPositionChanged: (drag) => {
+                               if (drag.hasUrls) {
+                                   root.activeZone = drag.x < globalDropArea.width / 2 ? "left" : "right"
+                               }
+                           }
+
+        onDropped: (drop) => {
+                       const targetZone = root.activeZone
+                       root.isDragActive = false
+                       root.filesCount = 0
+                       splitDropOverlay.opacity = 0
+
+                       Qt.callLater(function() {
+                           splitDropOverlay.visible = false
+                           root.activeZone = ""
+                       })
+
+                       if (!drop.hasUrls || drop.urls.length === 0) {
+                           return
+                       }
+
+                       var urlStrings = []
+                       for (var i = 0; i < drop.urls.length; i++) {
+                           var urlString = drop.urls[i].toString()
+                           if (urlString.startsWith("file://") || urlString.indexOf("://") === -1) {
+                               urlStrings.push(urlString)
+                           }
+                       }
+
+                       if (urlStrings.length === 0) {
+                           return
+                       }
+
+                       drop.accept(Qt.CopyAction)
+
+                       if (targetZone === "right") {
+                           root.filesDroppedToLink(urlStrings)
+                       } else {
+                           root.filesDroppedToAttach(urlStrings)
+                       }
+                   }
+    }
+}
+

sources/ChatView/qml/controls/Toast.qml

@@ -0,0 +1,88 @@
+// Copyright (C) 2025-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+
+Rectangle {
+    id: root
+
+    property alias toastTextItem: textItem
+    property alias toastTextColor: textItem.color
+
+    property string errorText: ""
+    property int displayDuration: 7000
+
+    width: Math.min(parent.width - 40, textItem.implicitWidth + radius)
+    height: visible ? (textItem.implicitHeight + 12) : 0
+    anchors.horizontalCenter: parent.horizontalCenter
+    anchors.top: parent.top
+    anchors.topMargin: 10
+
+    color: "#d32f2f"
+    radius: height / 2
+    border.color: "#b71c1c"
+    border.width: 1
+    visible: false
+    opacity: 0
+
+    TextEdit {
+        id: textItem
+
+        anchors.centerIn: parent
+        anchors.margins: 6
+        text: root.errorText
+        color: palette.text
+        font.pixelSize: 13
+        wrapMode: TextEdit.Wrap
+        width: Math.min(implicitWidth, root.parent.width - 60)
+        horizontalAlignment: TextEdit.AlignHCenter
+        readOnly: true
+        selectByMouse: true
+        selectByKeyboard: true
+        selectionColor: "#b71c1c"
+    }
+
+    function show(message) {
+        errorText = message
+        visible = true
+        showAnimation.start()
+        hideTimer.restart()
+    }
+
+    function hide() {
+        hideAnimation.start()
+    }
+
+    NumberAnimation {
+        id: showAnimation
+
+        target: root
+        property: "opacity"
+        from: 0
+        to: 1
+        duration: 200
+        easing.type: Easing.OutQuad
+    }
+
+    NumberAnimation {
+        id: hideAnimation
+
+        target: root
+        property: "opacity"
+        from: 1
+        to: 0
+        duration: 200
+        easing.type: Easing.InQuad
+        onFinished: root.visible = false
+    }
+
+    Timer {
+        id: hideTimer
+
+        interval: root.displayDuration
+        running: false
+        repeat: false
+        onTriggered: root.hide()
+    }
+}

sources/ChatView/qml/controls/TopBar.qml

@@ -0,0 +1,361 @@
+// Copyright (C) 2024-2026 Petr Mironychev
+// SPDX-License-Identifier: GPL-3.0-or-later
+// Additional attribution terms under GPLv3 §7(b) apply — see LICENSE
+
+import QtQuick
+import QtQuick.Layouts
+import QtQuick.Controls
+import ChatView
+import UIControls
+
+Rectangle {
+    id: root
+
+    property bool isInEditor: false
+
+    property alias saveButton: saveButtonId
+    property alias loadButton: loadButtonId
+    property alias clearButton: clearButtonId
+    property alias newChatButton: newChatButtonId
+    property alias tokensBadge: tokensBadgeId
+    property alias recentPath: recentPathId
+    property alias openChatHistory: openChatHistoryId
+    property alias pinButton: pinButtonId
+    property alias relocateButton: relocateButtonId
+    property alias contextButton: contextButtonId
+    property alias toolsButton: toolsButtonId
+    property alias thinkingMode: thinkingModeId
+    property alias settingsButton: settingsButtonId
+    property alias configSelector: configSelectorId
+    property alias roleSelector: roleSelector
+    property alias relocateTooltip: relocateTooltipId
+
+    color: palette.window.hslLightness > 0.5 ?
+               Qt.darker(palette.window, 1.1) :
+               Qt.lighter(palette.window, 1.1)
+
+    Flow {
+        anchors {
+            left: parent.left
+            right: parent.right
+            verticalCenter: parent.verticalCenter
+            margins: 5
+        }
+        spacing: 10
+
+        Row {
+            id: firstRow
+
+            spacing: 10
+
+            QoAButton {
+                id: pinButtonId
+
+                anchors.verticalCenter: parent.verticalCenter
+                checkable: true
+
+                icon {
+                    source: checked ? "qrc:/qt/qml/ChatView/icons/window-lock.svg"
+                                    : "qrc:/qt/qml/ChatView/icons/window-unlock.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: pinButtonId.hovered
+                    delay: 250
+                    text: pinButtonId.checked ? qsTr("Unpin chat window")
+                                              : qsTr("Pin chat window to the top")
+                }
+            }
+
+            QoAButton {
+                id: relocateButtonId
+
+                anchors.verticalCenter: parent.verticalCenter
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/open-in-editor.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    id: relocateTooltipId
+
+                    visible: relocateButtonId.hovered
+                    delay: 250
+                }
+            }
+
+            QoASeparator {
+                anchors.verticalCenter: parent.verticalCenter
+            }
+
+            QoAButton {
+                id: clearButtonId
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/clean-icon-dark.svg"
+                    height: 15
+                    width: 8
+                }
+
+                QoAToolTip {
+                    visible: clearButtonId.hovered
+                    delay: 250
+                    text: qsTr("Clean chat")
+                }
+            }
+
+            QoASeparator {
+                anchors.verticalCenter: parent.verticalCenter
+            }
+
+            QoAButton {
+                id: newChatButtonId
+
+                visible: root.isInEditor
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/new-chat-icon.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: newChatButtonId.hovered
+                    delay: 250
+                    text: qsTr("Open new chat in a new tab")
+                }
+            }
+
+            QoAComboBox {
+                id: configSelectorId
+
+                implicitHeight: 25
+
+                model: []
+                currentIndex: 0
+
+                QoAToolTip {
+                    visible: configSelectorId.hovered
+                    delay: 250
+                    text: qsTr("Switch saved AI configuration")
+                }
+            }
+
+            QoAComboBox {
+                id: roleSelector
+
+                implicitHeight: 25
+
+                model: []
+                currentIndex: 0
+
+                QoAToolTip {
+                    visible: roleSelector.hovered
+                    delay: 250
+                    text: qsTr("Switch agent role (different system prompts)")
+                }
+            }
+        }
+
+        Row {
+            spacing: 10
+
+            QoAButton {
+                id: toolsButtonId
+
+                anchors.verticalCenter: parent.verticalCenter
+
+                checkable: true
+                opacity: enabled ? 1.0 : 0.2
+
+                icon {
+                    source: checked ? "qrc:/qt/qml/ChatView/icons/tools-icon-on.svg"
+                                    : "qrc:/qt/qml/ChatView/icons/tools-icon-off.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: toolsButtonId.hovered
+                    delay: 250
+                    text: {
+                        if (!toolsButtonId.enabled) {
+                            return qsTr("Tools are disabled in General Settings")
+                        }
+                        return toolsButtonId.checked
+                                ? qsTr("Tools enabled: AI can use tools to read files, search project, and build code")
+                                : qsTr("Tools disabled: Simple conversation without tool access")
+                    }
+                }
+            }
+
+            QoAButton {
+                id: thinkingModeId
+
+                anchors.verticalCenter: parent.verticalCenter
+
+                checkable: true
+                opacity: enabled ? 1.0 : 0.2
+
+                icon {
+                    source: checked ? "qrc:/qt/qml/ChatView/icons/thinking-icon-on.svg"
+                                    : "qrc:/qt/qml/ChatView/icons/thinking-icon-off.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: thinkingModeId.hovered
+                    delay: 250
+                    text: thinkingModeId.enabled
+                        ? (thinkingModeId.checked ? qsTr("Thinking Mode enabled (Check model list support it)")
+                                                  : qsTr("Thinking Mode disabled"))
+                        : qsTr("Thinking Mode is not available for this provider")
+                }
+            }
+
+            QoAButton {
+                id: settingsButtonId
+
+                anchors.verticalCenter: parent.verticalCenter
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/settings-icon.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: settingsButtonId.hovered
+                    delay: 250
+                    text: qsTr("Open Chat Assistant Settings")
+                }
+            }
+
+            QoASeparator {
+                anchors.verticalCenter: parent.verticalCenter
+            }
+        }
+
+
+        Item {
+            height: firstRow.height
+            width: recentPathId.width
+
+            Text {
+                id: recentPathId
+
+                anchors.verticalCenter: parent.verticalCenter
+                width: Math.min(implicitWidth, root.width)
+                elide: Text.ElideMiddle
+                color: palette.text
+                font.pixelSize: 12
+
+                MouseArea {
+                    anchors.fill: parent
+                    hoverEnabled: true
+
+                    QoAToolTip {
+                        visible: parent.containsMouse && recentPathId.text.length > 0
+                        text: recentPathId.text
+                        delay: 500
+                    }
+                }
+            }
+        }
+
+        RowLayout {
+            id: secondRow
+
+            Layout.preferredWidth: root.width
+            Layout.preferredHeight: firstRow.height
+
+            spacing: 10
+
+            QoAButton {
+                id: saveButtonId
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/save-chat-dark.svg"
+                    height: 15
+                    width: 8
+                }
+
+                QoAToolTip {
+                    visible: saveButtonId.hovered
+                    delay: 250
+                    text: qsTr("Save chat to *.json file")
+                }
+            }
+
+            QoAButton {
+                id: loadButtonId
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/load-chat-dark.svg"
+                    height: 15
+                    width: 8
+                }
+
+                QoAToolTip {
+                    visible: loadButtonId.hovered
+                    delay: 250
+                    text: qsTr("Load chat from *.json file")
+                }
+            }
+
+            QoAButton {
+                id: openChatHistoryId
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/file-in-system.svg"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: openChatHistoryId.hovered
+                    delay: 250
+                    text: qsTr("Show in system")
+                }
+            }
+
+            QoASeparator {}
+
+            QoAButton {
+                id: contextButtonId
+
+                icon {
+                    source: "qrc:/qt/qml/ChatView/icons/context-icon.svg"
+                    color: palette.window.hslLightness > 0.5 ? "#000000" : "#FFFFFF"
+                    height: 15
+                    width: 15
+                }
+
+                QoAToolTip {
+                    visible: contextButtonId.hovered
+                    delay: 250
+                    text: qsTr("View chat context (system prompt, role, rules)")
+                }
+            }
+
+            Badge {
+                id: tokensBadgeId
+
+                ToolTip.visible: hovered
+                ToolTip.delay: 250
+                ToolTip.text: qsTr("Current amount tokens in chat and LLM limit threshold")
+            }
+        }
+    }
+}